RegisterUserFuncX: Register Methods To All QTP Objects Automatically

by Anshoo Arora ON December 8, 2009 · Posted In All, QTP · 36 comments

Let’s suppose we have a function called GetProperty, which we would like to register to all objects available to us. Now, if we do it manually, it can be quite time-consuming since any sort of AUT has many objects, and if you’re working in an environment where multiple technologies are involved, this can even get a little boring. Now, though, there is a simple way of register all our objects to the function by simply calling the method RegisterUserFuncX.

Before we see how the method RegisterUserFuncX works, let’s create a function GetProperty function, which we will first manually register to the objects in our multi-technology (Standard Windows, Web, Siebel) AUT:

Function GetProperty(Object)
    GetProperty = Object.GetTOProperty("micclass")
End Function

'Web
RegisterUserFunc "Link", "GetProperty", "GetProperty"
RegisterUserFunc "WebEdit", "GetProperty", "GetProperty"
 
'Standard Windows
RegisterUserFunc "WinEditor", "GetProperty", "GetProperty"
 
'Siebel
RegisterUserFunc "SiebList", "GetProperty", "GetProperty"

Now, this is just an example. There are obviously many more objects I would have to register the function with. However, instead of doing this manually, I can simply use the below method and register any given function to all objects automatically:

Function RegisterUserFuncX(TOMethodName, FunctionName)
    Dim oRegistry, arrSubKeys, sSubKey, sKeyPath
    Const HKEY_LOCAL_MACHINE = &H80000002
 
    sKeyPath = "SOFTWARE\MERCURY INTERACTIVE\QuickTest Professional\MicTest\Test Objects"
 
    Set oRegistry = GetObject("winmgmts:{impersonationLevel=impersonate}!\\." &_ 
                    "\root\default:StdRegProv")
 
    oRegistry.EnumKey HKEY_LOCAL_MACHINE, sKeyPath, arrSubKeys
 
    For Each sSubKey In arrSubKeys
        RegisterUserFunc sSubKey, TOMethodName, FunctionName
    Next
 
    Set oRegistry = Nothing
End Function

If we have to associate all objects in our AUT to the custom function, we would just call the above method once to do our job:

Call RegisterUserFuncX("GetProperty", "GetProperty")

This is the equivalent of registering the GetProperty method to all objects manually – which requires writing many individual RegisterUserFunc statements. The concept behind this method is that in the following folder of our Registry (regedit), we have all the objects stored:

HKEY_LOCAL_MACHINE\SOFTWARE\MERCURY INTERACTIVE\QuickTest Professional\MicTest\Test Objects

Therefore, instead of registering single object classes to our function, we can use the method RegisterUserFuncX and register any given function to all objects at once. The above function can also be tweaked to only register Web Objects, or Windows, or objects of an environment of your choice. This would involve manipulating the For..Each loop a bit:

'Register all the Web Objects
For Each sSubKey In arrSubKeys
    If InStr(1, sSubKey, "Web") > 0 Then
        RegisterUserFunc sSubKey, TOMethodName, FunctionName
    End If
Next

Limitations

This technique doesn’t well as its supposed to in terms of Siebel Objects (See Tarun’s comment here). This is because the Siebel Objects in the Registry are named differently as opposed to how the Object Spy identifies them. Objects in the Registry are named as “Sbl..” as opposed to “Sieb..”, which is the main reason for this shortcoming.
The above limitation has been resolved: Certain objects are available in QTP’s DAT folder, and by modifying the actual code in this post for XMLs, all objects can still be registered easily to custom methods. Credits go to Motti for reporting this resolution.
Another limitation of this approach is due to the dynamically executing RegisterUserFunc statements, which end up in the lack of Intellisense during test-design. This can be overcome by using RegisterUserFuncX to print all the necessary RegisterUserFunc statements and pasting the output to our libraries. See Tarun’s comment here.

Tagged as: QTP Register, QTP Register Function, QTP Register Method, QTP RegisterUserFunc, RegisterUserFunc, RegisterUserFuncX

Leave a Comment

{ 35 comments… read them below or add one }

ravi May 2, 2012 at 6:15 am

i just wanted to know when to use this registerUserFunc . at what situations the usage will come in to picture. can u pls help me out.
Thanks in Advance.

RegisterUserFuncX: Register Methods To All QTP Objects Automatically

Limitations

Tags

Recent Comments

Subscribe

CONNECT