QTP: Verify Multiple Object Properties – An Elegant Approach

by Anshoo Arora ON August 10, 2009 · Posted In All, QTP · 31 comments

Article revised on 04/04/2012

This article discusses an elegant way of cross-checking expected vs actual properties of objects. The two important components of this technique are:

Modular Classes
DoPropertiesConform Method

Modular Classes

The main concept behind this technique is the usage of a Dictionary object to hold property-value pairs. There are 2 types of Dictionary objects used in Modular Classes: a Base (Parent) Dictionary and one (or more) Child Dictionaries. All Child Dictionaries are stored in a single Base Dictionary and passed through the class method. In practice, if we’re checking properties for the LogIn page, the Login Class will contain a Base Dictionary and several Child Dictionaries. Example:

Class LoginModule
 
    Public Function Collection
        Dim BaseDictionary 'A Single Parent Dictionary
  
        Dim Search   '1st Child Dictionary
        Dim SiteLogo '2nd Child Dictionary
          
        Set BaseDictionary = CreateObject("Scripting.Dictionary")
        Set Search = CreateObject("Scripting.Dictionary")
        Set SiteLogo = CreateObject("Scripting.Dictionary")
    End Function
 
End Class

Above, we created 3 dictionaries: 1 Parent and 2 Child. Now, let’s add some properties to the Child Dictionaries:

Class LoginModule
 
    Public Function Collection
        Dim BaseDictionary 'A Single Parent Dictionary
  
        Dim Search   '1st Child Dictionary
        Dim SiteLogo '2nd Child Dictionary
          
        Set BaseDictionary = CreateObject("Scripting.Dictionary")
        Set Search = CreateObject("Scripting.Dictionary")
        Set SiteLogo = CreateObject("Scripting.Dictionary")
 
        With Search
            .Add "Me", Browser("title:=Google").Page("micclass:=Page").WebEdit("name:=q")
            .Add "html tag", "INPUT"
            .Add "width", 100
        End With
 
        With SiteLogo
            .Add "Me", Browser("title:=Google").Page("micclass:=Page").Image("file name:=logo.gif")
            .Add "html tag", "IMG"
            .Add "width", 50
        End With
    End Function
 
End Class

Above, we added properties to the 2 Child Dictionaries. Please note that, the very first item/key in the dictionary in the Child Dictionaries is the object itself. I have used “Me” denoting that it is the object itself; you can change “Me” to any other descriptive term. However, the first item in the Collection must always be the object. Finally, let’s pass the Child Dictionaries through the method with the help of the Parent Dictionary:

Class LoginModule
 
    Public Function Collection
        Dim BaseDictionary  'A Single Parent Dictionary
  
        Dim Search    '1st Child Dictionary (Search WebEdit)
        Dim SiteLogo  '2nd Child Dictionary (SiteLogo Image)
          
        Set BaseDictionary = CreateObject("Scripting.Dictionary")
        Set Search = CreateObject("Scripting.Dictionary")
        Set SiteLogo = CreateObject("Scripting.Dictionary")
 
        With Search
            .Add "Me", Browser("title:=Google").Page("micclass:=Page").WebEdit("name:=q")
            .Add "html tag", "INPUT"
            .Add "width", 100
        End With
 
        With SiteLogo
            .Add "Me", Browser("title:=Google").Page("micclass:=Page").Image("file name:=logo.gif")
            .Add "html tag", "IMG"
            .Add "width", 50
        End With
 
        With BaseDictionary
            .Add "Search", Search
            .Add "SiteLogo", SiteLogo
        End With
 
        Set Collection = BaseDictionary
    End Function
 
End Class

Above, we passed the Parent (Base) Dictionary containing both child Dictionary objects through the method. One last thing here. We must dispose all objects when we’re done (we will have to declare the variables in the Class scope, instead of method scope):

Class LoginModule
 
    Private BaseDictionary 'Parent Dictionary (Class Scope)
    Private Search         'Child Dictionary 1 (Class Scope)
    Private SiteLogo       'Child Dictionary 2 (Class Scope)
 
 
    Public Function Collection
        Set BaseDictionary = CreateObject("Scripting.Dictionary")
        Set Search = CreateObject("Scripting.Dictionary")
        Set SiteLogo = CreateObject("Scripting.Dictionary")
 
        'Child Dictionary #1
        With Search
            .Add "Me", Browser("title:=Google").Page("micclass:=Page").WebEdit("name:=q")
            .Add "html tag", "INPUT"
            .Add "width", 100
        End With
 
        'Child Dictionary #2
        With SiteLogo
            .Add "Me", Browser("title:=Google").Page("micclass:=Page").Image("file name:=logo.gif")
            .Add "html tag", "IMG"
            .Add "width", 50
        End With
 
        'Add the Child Dictionary objects to Base
        With BaseDictionary
            .Add "Search", Search
            .Add "SiteLogo", SiteLogo
        End With
 
        Set Collection = BaseDictionary
    End Function
 
    Public Sub Dispose
        BaseDictionary.RemoveAll : Set BaseDictionary = Nothing
        Search.RemoveAll : Set Search = Nothing
        SiteLogo.RemoveAll : Set SiteLogo = Nothing
    End Sub
 
End Class

The Modular class is ready and holds a Base collection with several Child collections.

DoPropertiesConform

This is where all the magic happens (simply keep it in one of your Global libraries and you’re good to go). This method verifies all the properties stored in the BaseDictionary with the runtime object properties. The final results are reported through Reporter events as HTML tables. The input to this method is the parent dictionary.

'Arg:
'    DictBase - Base Collection - this contains several child collections
'Returns:
'    Boolean (True if all properties in the collection match)

Public Function DoPropertiesConform(ByVal DictBase)
    Dim vKeys, intStatus, i, m_ContextTemp, bResult, keysTemp, oTemp, x, sStatus, css, StepInfo
 
    DoPropertiesConform = False
 
    vKeys = DictBase.Keys
    intStatus = micPass
 
    For i = 0 to DictBase.Count-1
        ' The below will create temporary references to Collection
        ' In our test, the Collection contains two objects: "Logo" and "UserName"
        Set m_ContextTemp = DictBase.Item(vKeys(i))
        bResult = bResult & "<table id='custom' border='1'><tr><th>" & _
                    "Status</th><th>Property</th><th>Expected</th><th>Actual</th></tr>"
        keysTemp = m_ContextTemp.Keys
 
        If m_ContextTemp.Item(keysTemp(0)).Exist(0) Then
            ' Create a temporary reference to the object in the base collection
            ' Key values for these objects must always start with "Me"
            Set oTemp = m_ContextTemp.Item(keysTemp(0))
 
            For x = 1 to m_ContextTemp.Count - 1
                sStatus = "<span style='color:green;'>Pass</span>"
 
                If Not CStr(oTemp.GetROProperty(keysTemp(x))) = CStr(m_ContextTemp.Item(keysTemp(x))) Then
                    intStatus = micWarning
                    sStatus = "<span style='color:orange;'>Warning</span>"
                End If
 
                bResult = bResult & "<tr><td>" & _
                            sStatus & "</td><td>" & _
                            KeysTemp(x)& "</td><td>" & _ 
                            m_ContextTemp.Item(keysTemp(x)) & "</td><td>" & _
                            oTemp.GetROProperty(keysTemp(x))& "</td></tr>"
            Next
 
            Set m_ContextTemp = Nothing
            bResult = bResult & "</table>" & vbLf
        End If
    Next
 
    css = "<style>#custom {font-family: Calibri, Arial;font-size: 12px;background: #fff;" & _
            "margin: 10px;width: 480px;border-collapse: collapse;text-align: left;}" & _
            "#custom th{font-size: 14px;font-weight: normal;color: #039;padding: 10px 8px;" & _
            "border-bottom: 2px solid #6678b1;}#custom td{border-bottom: 1px solid #ccc;color:" & _
            "#669;padding: 6px 8px;}#custom tbody tr:hover td{color: #009;}</style><body>"
 
    Set StepInfo = CreateObject("Scripting.Dictionary")
    StepInfo("ViewType") = "Sell.Explorer.2"
    StepInfo("DllIconIndex") = 206
    StepInfo("DllIconSelIndex") = StepInfo("DllIconIndex")
    StepInfo("DllPAth") = Environment.Value("ProductDir") & "\bin\ContextManager.dll"
    StepInfo("Status") = intStatus
    StepInfo("NodeName") = "DoPropertiesConform"
    StepInfo("StepHtmlInfo") = "<html>" & css & bResult & "</body></html>"
 
    Reporter.LogEvent "User", StepInfo, Reporter.GetContext
 
    If intStatus = micPass Then DoPropertiesConform = True
 
    Set DictBase = Nothing
    Set m_ContextTemp = Nothing
End Function

Once we have added all the relevant objects and their properties to the parent dictionary, it just takes the following line of code to run all the verifications:

Call DoPropertiesConform(ParentDictionary)

Example

In the example below, we will verify expected and actual properties of the Site Logo and the UserName WebEdit for the Mercury/HP Demo Web Application. Below are the snapshots of the 2 objects verified in the examples:

Site Logo

Class HomePage
 
    Private m_ContextBase      'Parent
    Private m_ContextLogo      'Child 1
    Private m_ContextUserName  'Child 2
    
    Public Function Collection
        ' Parent Dictionary (Base)
        Set m_ContextBase = CreateObject("Scripting.Dictionary")
 
        ' Child Dictionary objects
        Set m_ContextLogo = CreateObject("Scripting.Dictionary")
        Set m_ContextUserName = CreateObject("Scripting.Dictionary")
 
        ' Properties of the Object: Site Logo Image
        With m_ContextLogo
            ' Actual Object is the first Item/Key
            .Add "Me", Browser( "title:=Welcome: Mercury Tours" ).Image( "file name:=logo.gif" )
            .Add "alt", "Mercury Tours"
            .Add "file name", "logo.gif"
            .Add "height", "110"
            .Add "name", "Image"
            .Add "width", "100"
        End With
 
        ' Properties of the Object: UserName WebEdit
        With m_ContextUserName
            ' The first Item/Key must always contain the object
            .Add "Me", Browser( "title:=Welcome: Mercury Tours" ).WebEdit( "name:=userName" )
            .Add "disabled", "0"
            .Add "height", "22"
            .Add "kind", "singleline"
            .Add "name", "userName"
            .Add "readonly", "0"
            .Add "rows", "0"
            .Add "type", "text"
            .Add "width", "86"
        End With
 
        ' The Parent Dictionary stores both Child Dictionaries
        With m_ContextBase
            .Add "Logo", m_ContextLogo
            .Add "UserName", m_ContextUserName
        End With
 
        Set Collection = m_ContextBase
    End Function
 
    Public Sub Dispose
        Set m_ContextBase = Nothing
        Set m_ContextLogo = Nothing
        Set m_ContextUserName = Nothing
    End Sub
 
End Class

' Usage:
Dim NewHomePage
Set NewHomePage = New HomePage
 
DoPropertiesConform NewHomePage.Collection
NewHomePage.Dispose

Result:

Result

I hope you guys find this article useful :)

Tagged as: Dictionary, DoPropertiesConform, Properties, QTP, QTP Check Object Properties, QTP Multiple Properties, QTP Verify Object Properties

Leave a Comment

{ 28 comments… read them below or add one }

Deepak December 10, 2009 at 6:02 am

hi Anshoo,

I need to say that ‘It is a great article.’ I have a question for you.

Why do you pass the value If intStatus micPass Then DoPropertiesConform = False

you are not using it anywhere?

Thanks,
-Deepak

QTP: Verify Multiple Object Properties – An Elegant Approach

Modular Classes

DoPropertiesConform

Example

Result:

Tags

Recent Comments

Subscribe

CONNECT