QTP: Using VBScript Classes as Test Modules I

by Anshoo Arora ON August 12, 2009 · Posted In All, QTP · 51 comments

Using Classes as Test Modules in QTP (Part I).

In this article, techniques of creating modular classes will be demonstrated. Usage of modular classes helps in keeping all methods and properties for a module intact, and if done correctly, this can simply maintenance greatly. This article serves as an introduction to Class usage in QTP. In the coming articles, we will discover advanced concepts in building highly stable and robust class modules.

Each modular class can contain one or more methods, which provide some functionality to a framework. Before adding the appropriate methods, we must create a modular class. In our demonstration, ‘clsLogin’ has been created, which as the name suggests, is a Login class.

Class clsLogin
 
End Class

The goal of the class we created above is to Login to the Mercury Tours website. Let’s name our method ‘Login’ and include the steps that the method will perform:

Class clsLogin
 
    ' Login
    Public Function Login( sUserName, sPassword )
        'Page title
        Dim sTitle: sTitle = "Welcome: Mercury Tours"
 
        Login = False
 
        With Browser( "title:=" & sTitle ).Page( "title:=" & sTitle )
            'Set the userName
            .WebEdit( "name:=userName" ).Set sUserName
            'Set the password
            .WebEdit( "name:=password" ).SetSecure sPassword
            'Click SignIn
            .Image( "name:=login" ).Click
        End With
 
        'If the correct Page appears: Step Passed
        If Browser( "title:=Find a Flight: Mercury Tours:" ).Exist( 5 ) Then
            Login = True
        End If
    End Function
 
End Class

Let’s assume we have to check properties of the page banner, which is a part of our test-case. In reality, there may be multiple objects for which properties are being verified and they can be included within the same method. For our example though, we will verify property of a single object: page banner.

Class clsLogin
 
    ' CheckObjectProperties
    Public Function CheckObjectProperties
        'Page title
        Dim sTitle: sTitle = "Welcome: Mercury Tours"
 
        CheckObjectProperties = False
 
        With Browser("title:=" & sTitle).Page("title:=" & sTitle)
            'Check Page Banner
            If .Image("file name:=banner2.gif").GetROProperty("width") = 488 Then
                'If the width equals the expected width, step passed
                CheckObjectProperties = True
                Reporter.ReportEvent micPass, "Banner", "Size Correct."
            Else
                Reporter.ReportEvent micFail, "Banner", "Size Incorrect."
            End If
        End With
    End Function
 
    ' Login
    Public Function Login( sUserName, sPassword )
        Dim sTitle: sTitle = "Welcome: Mercury Tours"
 
        Login = False
 
        With Browser( "title:=" & sTitle ).Page( "title:=" & sTitle )
            'Set the userName
            .WebEdit( "name:=userName" ).Set sUserName
            'Set the password
            .WebEdit( "name:=password" ).SetSecure sPassword
            'Click SignIn
            .Image( "name:=login" ).Click
        End With
 
        Browser( "title:=" & sTitle ).Sync
 
        'If the correct Page appears: Step Passed.
        If Browser( "title:=Find a Flight: Mercury Tours:" ).Exist( 5 ) Then 
            Login = True
        End If
    End Function
 
End Class

The 2 methods discussed above are quite common: we generally perform actions on objects and create checks to replace (manual) visual verifications. Now, before we can really perform the above 2 checks, we may also need to check whether we’re on the correct page. Let’s add another method for that:

Class clsLogin
 
    ' IsPageFound: Check if we're on the correct page
    Public Function IsPageFound
        'Page title
        Dim sTitle: sTitle = "Welcome: Mercury Tours"
 
        IsPageFound = False
 
        With Browser( "title:=" & sTitle ).Page( "title:=" & sTitle )
            If .Exist( 10 ) Then
                IsPageFound = True
            End If
        End With
    End Function
 
    ' CheckObjectProperties
    Public Function CheckObjectProperties
        Dim sTitle: sTitle = "Welcome: Mercury Tours"
 
        CheckObjectProperties = False
 
        With Browser( "title:=" & sTitle ).Page( "title:=" & sTitle )
            'Check Page Banner
            If .Image("file name:=banner2.gif").GetROProperty("width") = 488 Then
                CheckObjectProperties = True
                Reporter.ReportEvent micPass, "Banner", "Size Correct."
            Else
                Reporter.ReportEvent micFail, "Banner", "Size Incorrect."
            End If
        End With
    End Function
 
    ' Login
    Public Function Login( sUserName, sPassword )
        Dim sTitle: sTitle = "Welcome: Mercury Tours"
 
        Login = False
 
        With Browser( "title:=" & sTitle ).Page( "title:=" & sTitle )
            'Set the userName
            .WebEdit( "name:=userName" ).Set sUserName
            'Set the password
            .WebEdit( "name:=password" ).SetSecure sPassword
            'Click SignIn
            .Image( "name:=login" ).Click
        End With
 
        'If the correct Page appears: Step Passed.
        If Browser( "title:=Find a Flight: Mercury Tours:" ).Exist( 5 ) Then 
            Login = True
        End If
    End Function
 
End Class

If we observe the code above, the variable “sTitle” is present in each method. This is quite redundant. We can simply replace this with a readOnly property:

Class clsLogin
 
    ' Property sTitle
    Private Property Get sTitle 'ReadOnly Property
        sTitle = "Welcome: Mercury Tours"
    End Property
 
    ' IsPageFound
    Public Function IsPageFound
        IsPageFound = False
 
        With Browser( "title:=" & sTitle ).Page( "title:=" & sTitle )
            If .Exist( 10 ) Then
                IsPageFound = True
            End If
        End With
    End Function
 
    ' CheckObjectProperties
    Public Function CheckObjectProperties
        CheckObjectProperties = False
 
        With Browser( "title:=" & sTitle ).Page( "title:=" & sTitle )
 
            'Check Page Banner
            If .Image("file name:=banner2.gif").GetROProperty("width") = 488 Then
                CheckObjectProperties = True
                Reporter.ReportEvent micPass, "Banner", "Size Correct."
            Else
                Reporter.ReportEvent micFail, "Banner", "Size Incorrect."
            End If
 
        End With
    End Function
 
    ' Login
    Public Function Login( sUserName, sPassword )
        Login = False
 
        With Browser( "title:=" & sTitle ).Page( "title:=" & sTitle )
            'Set the userName
            .WebEdit( "name:=userName" ).Set sUserName
            'Set the password
            .WebEdit( "name:=password" ).SetSecure sPassword
            'Click SignIn
            .Image( "name:=login" ).Click
        End With
 
        'If the correct Page appears: Step Passed.
        If Browser( "title:=Find a Flight: Mercury Tours:" ).Exist( 5 ) Then 
            Login = True
        End If
    End Function
 
End Class

Even though some methods of a class are crucial, they may only perform background operations. In our demonstration, IsPageFound and CheckObjectProperties are such methods. Both methods verify objects, and in the automation world, they can be very reasonable prerequisites to the main action, which is to Login to the application. In the demonstration below, IsPageFound and CheckObjectProperties have been marked as private. Both methods are included as a prerequisite to setting the userName and password for logging to the website. To reiterate, both IsPageFound and CheckObjectProperties can be made private methods of the class:

Class clsLogin
 
    ' IsPageFound: Private Function
    Private Function IsPageFound
        IsPageFound = False
 
        With Browser( "title:=" & sTitle ).Page( "title:=" & sTitle )
            If .Exist( 10 ) Then
                IsPageFound = True
            End If
        End With
    End Function
 
    ' CheckObjectProperties: Private Function
    Private Function CheckObjectProperties
        CheckObjectProperties = False
 
        With Browser( "title:=" & sTitle ).Page( "title:=" & sTitle )
 
            'Check Page Banner
            If .Image( "file name:=banner2.gif" ).GetROProperty( "width" ) = 488 Then
                CheckObjectProperties = True
                Reporter.ReportEvent micPass, "Banner", "Size Correct."
            Else
                Reporter.ReportEvent micFail, "Banner", "Size Incorrect."
            End If
 
        End With
    End Function
 
    ' Login: Public Function
    Public Function Login( sUserName, sPassword )
        Login = False
 
        If IsPageFound Then
            If CheckObjectProperties Then
                With Browser( "title:=" & sTitle ).Page( "title:=" & sTitle )
                    'Set the userName
                    .WebEdit( "name:=userName" ).Set sUserName
                    'Set the password
                    .WebEdit( "name:=password" ).SetSecure sPassword
                    'Click SignIn
                    .Image( "name:=login" ).Click
                End With
            End If
        End If
 
        'If the Page with the title 'Find a Flight: Mercury Tours:' appears: Step Passed.
        If Browser( "title:=Find a Flight: Mercury Tours:" ).Exist( 5 ) Then 
            Login = True
        End If
    End Function
 
    ' Property sTitle: Private Property
    Private Property Get sTitle
        sTitle = "Welcome: Mercury Tours"
    End Property
 
End Class

If you notice the code above, you will see that both private methods have become a part of the Login method. They’re both prerequisites to logging in to the application. Only once both are True, will the code perform the code-action of the class. We can implement the class above using the following snippet:

Public Function Login( sUserName, sPassword )
    Dim oAction: Set oAction = New clsLogin
    Login = oAction.Login( sUserName, sPassword )
End Function

If you would like to keep ‘IsPageFound’ and ‘CheckObjectProperties’ as public methods of the class, then you can even do this:

Public Function Login( sUserName, sPassword )
    Dim oAction: Set oAction = New clsLogin  
 
    Login = False
 
    With oAction
        If .IsPageFound Then
            If .CheckObjectProperties Then
                Login = .Login( sUserName, sPassword )
            End If
        End If
    End With
End Function

It is possible for a single function to do everything, but don’t you think its much easier to understand what each method of the class does with little effort? ‘IsPageFound’ simply checks if we’re on the correct page, ‘CheckObjectProperties’ checks if the object was loaded correctly, and ultimately, ‘Login’ performs to core-action by logging the user to the application. Moreover, all methods are grouped together in a class.

In practice, the entire test suite can be created on this principle with each module representing a core-functionality of the overall test. There are several ways to bind these modules together, and we must find an elegant solution for that as well. This is because, because of some major changes, we may need to completely remove a module, or even add one. Therefore, if done correctly, even such a big change can be implemented without much trouble. We will discuss such a technique in the next article in this series, which will be an advanced implementation of class usage in QTP.

I hope you guys find this article useful.

Tagged as: OOPs, QTP, QTP Classes, QTP Creating Classes, QTP Modular Classes, QTP Modules, QTP OOPs, QTP VBScript, QTP VBScript Classes, Test Module, VBScript OOPs

Leave a Comment

{ 50 comments… read them below or add one }

Shri January 29, 2012 at 12:59 am

Hi Anshoo,
I had the following query with the usage of classes in qtp.
I understand that it provides support for modularity (i.e. a Login Module is converted into a class file with methods say to perform operations on objects + validations as required by the user).
How should i go ahead and use this class / incorporate the same in my framework which is something i am not able to get clarity on.
i.e. where is the object for this class being initialized / What is Class_Initialize and Class_Terminate events?
How exactly is the calling for this incorporated in the larger scheme of your framework.

Thanks a lot,

QTP: Using VBScript Classes as Test Modules I

Tags

Recent Comments

Subscribe

CONNECT