Class clsGetROProperties
   Private arrProperties
   Private sObject
 
   Public Function GetProperties(Object)
      Dim arrObject, ix
 
      Set GetProperties = Nothing
 
      'Retrieve object type / Object Class
      sObject = Object.GetTOProperty("micclass")
 
      'If Object is found in Registry then, add all ROProperties to RecordSet
      If bObjectExistsInReg Then
         Const adVarChar = 200
 
         Set GetProperties = CreateObject("ADODB.RecordSet")
 
         'Add Properties available in the Registry
         For ix = LBound(arrProperties) to UBound(arrProperties)
            Select Case LCase(arrProperties(ix))
               Case ""
               Case Else
                  GetProperties.Fields.Append "" & arrProperties(ix), adVarChar, 2000
            End Select
         Next
 
         'Open the RecordSet Connection for Write Access
         GetProperties.Open : GetProperties.AddNew
 
         'Use .GetROProperty to retrieve and store all values in the RecordSet
         On Error Resume Next
         For ix = 0 to GetProperties.Fields.Count - 1
            GetProperties.Fields(ix).Value = Object.GetROProperty(GetProperties.Fields(ix).Name)
         Next
         On Error Goto 0
 
         GetProperties.Update
      End If
   End Function
 
   Private Function bObjectExistsInReg()
      Dim oRegistry, arrSubKeys, sSubKey
      Const HKEY_LOCAL_MACHINE = &H80000002
 
      bObjectExistsInReg = False
 
      Set oRegistry = GetObject("winmgmts:{impersonationLevel=impersonate}!\\." &_ 
                  "\root\default:StdRegProv")
 
      oRegistry.EnumKey HKEY_LOCAL_MACHINE, GetKeyPath, arrSubKeys
 
      For Each sSubKey In arrSubKeys
         'If Object Class matches one of the Registry Sub-Keys, then, 
         'drill-down to the Description folder of the key
         If UCase(sSubKey) = Trim(UCase(sObject)) Then
            oRegistry.EnumValues HKEY_LOCAL_MACHINE, GetKeyPath & "\" & _
               sSubKey & "\Description\", arrProperties
            bObjectExistsInReg = True
            Exit For
         End If
      Next
 
      Set oRegistry = Nothing
   End Function
 
   Private Property Get GetKeyPath()
      GetKeyPath = "SOFTWARE\MERCURY INTERACTIVE\QuickTest Professional\MicTest\Test Objects"
   End Property
End Class
 
Function GetROProperties(Object)
   Set GetROProperties = New clsGetROProperties
   Set GetROProperties = GetROProperties.GetProperties(Object)
End Function

'RegisterUserFuncX "GetROProperties", "GetROProperties"
RegisterUserFunc "WebEdit", "GetROProperties", "GetROProperties"
 
Set oROProperties = Browser("title:=Google").WebEdit("name:=q").GetROProperties
 
For ix = 0 to oROProperties.Fields.Count - 1
	Print oROProperties(ix).Name & " -> " & oROProperties(ix).Value
Next
 
Set oROProperties = Nothing

'RegisterUserFuncX "GetROProperties", "GetROProperties"
RegisterUserFunc "Link", "GetROProperties", "GetROProperties"
 
Set oROProperties = Browser("title:=Google").Link("innertext:=About Google").GetROProperties
 
For ix = 0 to oROProperties.Fields.Count - 1
	Print oROProperties(ix).Name & " -> " & oROProperties(ix).Value
Next
 
Set oROProperties = Nothing