Relevant Codes (by Anshoo Arora) » QTP/Siebel

QTP: Working With SiebList (Revised)

Anshoo Arora — Sun, 21 Mar 2010 02:29:44 +0000

The previous articles written for the Siebel category were written from a perspective of version 7.7 and 7.8. I know of many of you have already have upgrades Siebel to 8.1, and so have we! This gave me a chance to update my old article on the SiebList object. Not much has changed, actually, but the code here has been optimized for better performance and compatibility with the latest version. Information regarding its limitations has also been included.

Instead of using the code from this article directly in your libraries, please use the download link instead, as the download files include documentation.

The techniques in this article have been tested on QTP 9.5 and Siebel 8.1. I do not guarantee that the techniques will be supported in older versions of Siebel, but if they aren’t, I believe with a few minor tweaks, they should become workable.

Limitations

As present, descriptive programming is not the recommended technique for automating a Siebel List. This is a limitation which is caused by the CAS API which exposes the object during replay as a SiebList, although in record some internal objects are exposed. Therefore the spy and highlight will show us the SiebList, and also the child object will return 0, since only the table is exposed¹.
Any column not visible on the screen will not be accessed by QTP. This includes the column that are brought into picture using the horizontal scroll-bar.
There are certain operations that do not perform well, and my personal recommendation would be to explore if usage of native methods are possible on the target objects.
Document ID KM204700 in HP’s KB lists a limitation which states a limitation in accessing cell items of a SiebList.

Find the Total Number of Records (Rows) in a SiebList

In the previous version of this article, the only possible way demonstrated to retrieve the row count from a Siebel List was through the RecordCounter. However, there is another (faster) way which is through the use of the shortcut keys to retrieve the number of rows. The shortcut keys that can be used to retrieve the total rows are: CTRL+SHIFT+3.

Record Count ShortCut

When using the shortcut, a will appear containing the record count:

Record Count

The following function shows the entire process of using the shortcut keys and retrieving the count from the window above:

Using Short-Cut Keys: CTRL+SHIFT+3

'--------------------------------------------------------
' Name: Function GetSiebListRecords
'
' Remarks: N/A
'
' Purpose: Retrieve the number of records (rows) from a Siebel List
'    using short-cut keys ctrl+shift+3
'    
' Arguments:
'    sBrowserTitle: Title of the Siebel Browser
'
' Return: Integer
'
' Author: Anshoo Arora, Relevant Codes
'
' Date: 03/17/2010
'
' References: N/A
'--------------------------------------------------------
Function GetSiebListRecords(sBrowserTitle)
    Dim oWScript, oRegExp, oMatches, sText
 
    GetSiebListRecords = -1
 
    Window("hwnd:=" & Browser("title:=" & sBrowserTitle).Object.HWND).Activate
 
    Set oWScript = CreateObject("WScript.Shell")
    oWScript.SendKeys "^+3"
 
    With Browser("opentitle:=SiebWebPopupWindow")
        While Not .Exist(0)
            Wait(2)
        Wend
 
        sText = .WebElement("innertext:=.*records.*", "index:=1").GetROProperty("innertext")
 
        Window("hwnd:=" & .Object.HWND).Close
    End With
 
    Set oRegExp = New RegExp
    oRegExp.Global = False
    oRegExp.Pattern = "\d+"
 
    Set oMatches = oRegExp.Execute(sText)
 
    If oMatches.Count > 0 Then GetSiebListRecords = CInt(oMatches(0))
 
    Set oWScript = Nothing
    Set oRegExp = Nothing
    Set oMatches = Nothing
End Function

Download: GetSiebListRecords Using ShortCut (149)

When there are many rows present in SiebList, it may not show the exact number. Instead it shows 1-10+ rows, 11-20+ rows, 21-30+ rows and so on. To get the correct number of rows from the List object, we use an the RecordCounter property of SiebApplet. RecordCounter indicates the visible text of the record counter string (for example: 1-10 or 10+). This is also the traditional (and slower) approach.

Traditional Method: RecordCounter

'--------------------------------------------------------
' Name: Function GetSiebListRecords
'
' Remarks: N/A
'
' Purpose: Retrieve the number of records (rows) from a Siebel List
'    using RecordCounter
'    
' Arguments:
'    oSiebApplet: Reference to the SiebApplet Hierarchy
'    sUINameSiebList: UIName of SiebList
'
' Return: Integer
'
' Author: Anshoo Arora, Relevant Codes
'
' Date: 03/17/2010
'
' References: N/A
'--------------------------------------------------------
Function GetSiebListRecords(oSiebApplet, sUINameSiebList)
    Dim iCnt
 
    If InStr(1, sUINameSiebList, "uiname") <> 0 Then
        sUINameSiebList = Trim(Split(sUINameSiebList, ":=")(1))
    End If
 
    iCnt = oSiebApplet.RecordCounter
 
    Do
        If Not InStr(1, iCnt, "+") <> 0 Then
            Exit Do
        Else
            oSiebApplet.SiebList("uiname:=" & sUINameSiebList).NextRowSet
            iCnt = oSiebApplet.RecordCounter
        End If
    Loop
 
    If InStr(1, iCnt, "of") <> 0 Then
        iCnt = CInt(Trim(Split(iCnt, "of")(1)))
    End If
 
    GetSiebListRecords = iCnt
End Function

Download: GetSiebListRecords Using RecordCounter (129)

Find a text string in the SiebList’s column

If the requirement is to find some text in one of the columns of the SiebList, we can loop over all the rows until we find the value that we’re looking for. Note that the column name may be different as it appears to the human eye. You will have to find the correct column name for this to work correctly. For example, in our environment, we have a column named Application Number. However, Application Number is what appears to us, but in reality, QuickTest identifies that column by Application ID.

'--------------------------------------------------------
' Name: Function FindSiebListRow
'
' Remarks: N/A
'
' Purpose: Find the Row from the provided Column (sColumnName) where
'    the given String (sText) exists.
'    
' Arguments:
'    oSiebApplet: Reference to the SiebApplet Hierarchy
'    sUINameSiebList: UIName of SiebList
'    sBrowserTitle: Title of the Siebel Browser
'    sColumnName: Name of the SiebList Column
'    sText: String to be searched
'
' Return: Integer
'
' Dependencies: Function GetSiebListRecords()
'
' Author: Anshoo Arora, Relevant Codes
'
' Date: 03/17/2010
'
' References: N/A
'--------------------------------------------------------
Function FindSiebListRow(oSiebApplet, sUINameSiebList, sBrowserTitle, sColumnName, sText)
    Dim iRows, iRow, sData
 
    If InStr(1, sUINameSiebList, "uiname") <> 0 Then
        sUINameSiebList = Trim(Split(sUINameSiebList, ":=")(1))
    End If
 
    'DEPENDANCY: GetSiebListRecords
    iRows = GetSiebListRecords(sBrowserTitle)
 
    With oSiebApplet.SiebList("uiname:=" & sUINameSiebList)
        .FirstRowSet
 
        For iRow = 0 to iRows - 1
            .ActivateRow iRow
 
            sData = Trim(.GetCellText(sColumnName, iRow))
 
            If CStr(sData) = CStr(sText) Then
                FindSiebListRow = iRow
                Exit Function
            End If
        Next
    End With
End Function

Download: FindSiebListRow (138)

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.

QTP Siebel Error: Test Execution halts when a SiebButton is clicked

Anshoo Arora — Fri, 16 Oct 2009 00:02:25 +0000

We had an issue with one of the SiebButton objects’ in our environment. When we executed a statement to click on this particular SiebButton, the next statement would not execute. What happens is, as we click this particular SiebButton, a Dialog box pops up immediately. For some reason that we have not been able to figure out, the execution marker from the SiebButton(“”).Click statement will not move to the next line. Instead, it just got stuck there, and stood there, forever.

We suspected that it may be because of a Modal Dialog that appears in the application preventing QTP from accessing the button. Another reason could be the poor performance of QTP & Siebel working together.

Below, you will see a rough demonstration of what happens:

'Click Sieb Button
SiebApplication("myApp").SiebScreen("myScreen").SiebView("myView")_
    .SiebApplet("myApplet").SiebButton("myButton").Click  'Dialog Opens and test halts here

'Execution marker never proceeds to the next statement:
Dialog("micclass:=Dialog").WinButton("text:=OK").Click

We were not able to figure out why the execution marker would not move on to the next line. We still haven’t figured it out. However, we found a workaround!

Instead of using one of the Siebel methods/descriptions to click the SiebButton, we used the Web framework (UI) event to click the SiebButton instead, which is viewed as a WebElement with just the Web-Addin loaded:

Browser("title:=Siebel.*").WebElement("text:=myButton", "index:=0").Click

This made the execution marker jump to the next execution line immediately, solved the issue that we were having and our script has been working brilliantly so far! If you have encountered an issue like this, please try this solution and even though I cannot guarantee that it will work, but chances are excellent that it might. :)

Credits go to Todd Mescher for working together with me to come to this fantastic resolution for an issue as strange as this. Thank you, Todd.

QTP: Working with Large Object Hierarchies (Siebel Objects)

Anshoo Arora — Thu, 17 Sep 2009 23:59:20 +0000

I received an e-mail from Suni Reddy, who asked me to share with her an easy way of working with Siebel objects – primarily because of their large object hierarchy. I have thought about it several times, but because our work on Siebel goes on a temporary basis, I was never able to come up with something. Until now. This article will describe how you can create a single library with all the parent objects and call those objects on demand.

Normally, if you would like to select an item from a SiebList, you would do something like:

SiebApplication("MyApplication").SiebScreen("MyScreen").SiebView("MyView")_
	.SiebApplet("MyApplet").SiebList("MyList").Select "Open"

The above hierarchy can be greatly simplified – and this article will show a few ways how it can be achieved. Also, the way we’re going to structure our hierarchy, changing one object in a single place will account for an overall change. In other words, instead of changing a single object multiple times (because something changed in the application) we’ll change it only once.

With Statements

This is by far the most common approach used when dealing with large hierarchies, and quite simple too. However, as the parent objects change, we end up creating more and more blocks of such statements. An example of With..End With statement in use:

With SiebApplication("MyApp").SiebScreen("MyScreen1").SiebView("MyView").SiebApplet("MyApplet")
	.SiebList("MyList").Select "Open"
	.SiebButton("MyButton").Click
End With
 
'SibScreen changes from MyScreen1 to MyScreen99: re-write.
With SiebApplication("MyApp").SiebScreen("MyScreen99").SiebView("MyView").SiebApplet("MyApplet")
	'your code
End With

Using Functions to Build Sieb Hierarchy

This technique uses several functions to build a complete hierarchy, but the result is a good one. Moreover, it also simplifies how events are performed on objects. Let’s start by building our first function for the base object (SiebApplication):

'Base Object: SiebApplication
Function oSiebApplication
	Set oSiebApplication = SiebApplication("MyApp")
End function

Let’s create instances for our Child objects:

'oSiebScreen retrieves its parent (oSiebApplication) from the function above
Function oSiebScreen
	Set oSiebScreen = oSiebApplication.SiebScreen("MyScreen")
End Function
 
'oSiebView_ retrieves its parent (oSiebScreen) from the function above
Function oSiebView
	Set oSiebView = oSiebScreen.SiebView("MyView")
End Functions
 
'oSiebApplet retrieves its parent (oSiebView) from the function above
Function oSiebApplet
	Set oSiebApplet = oSiebView.SiebApplet("MyApplet")
End Function

To demonstrate, if we want to set a value in the “lstApplication1″ SiebList, we can simply do the following:

oSiebApplet.SiebList("lstApplication1").Select "Urgent"

I hope the above concept is quite easy to follow, because its used in an OO-methodology below, but with the help of properties.

Using Classes

This is my favorite, and quite similar to what we have above, but, the advantage of using this technique is that we can have multiple classes for multiple Parents, or a single class to group them all together. Assume we have the following hierarchy with an event:

SiebApplication("MyApp").SiebScreen("MyScreen").SiebView("MyView")_
	.SiebApplet("MyApplet").SiebList("lstApplication1").Highlight

First, let’s create a sample class for the Base object(s) that will be common for all classes.

'Demo class for the top-most object (Parent Class)
Class clsSiebApplication
	Public Property Get oSiebApplication
		Set oSiebApplication = SiebApplication("MyApp")
	End Property
End Class

Now, let’s build the child classes, that will use the base class to complete object hierarchies:

'Child Class: Derives its Base Object from clsSiebApplication (Parent Class)
Class clsSiebObjects
	Private oShared
 
	'We will reuse the Base class to retrieve some common objects
	'An instance of the base class will be initialized as the class loads
	Private Sub Class_Initialize		
		Set oShared = new clsSiebApplication
	End Sub
 
	'Terminate the instance while exiting.
	Private Sub Class_Terminate		
		Set oShared = Nothing
	End Sub	
 
	'oSiebScreen Property will retrieve its parent from oSiebApplication
	Public Property Get oSiebScreen
		Set oSiebScreen = oShared.oSiebApplication.SiebScreen("MyScreen")
	End Property
 
	'oSiebView Property will retrieve its parent from oSiebScreen (above)
	Public Property Get oSiebView
		Set oSiebView = oSiebScreen.SiebView("MyView")
	End Property
 
	'oSiebApplet Property will retrieve its parent from oSiebView (above)
	Public Property Get oSiebApplet
		Set oSiebView = oSiebView.SiebApplet("MyApplet")
	End Property
End Class

This can be used in a fashion that makes it very easy for the reader to comprehend with which objects the script is working with. Let’s use the same example we used above with the “lstApplication1″ SiebList:

Dim oSieb
 
'Create an instance of clsSiebObjects
Set oSieb = New clsSiebObjects
 
'Performing an event on the SiebList Object
oSieb.SiebApplet.SiebList("lstApplication1").Highlight

Using an Object Dictionary

This technique is based on Meir’s article, Implementing a GUI Layer with Classes. I would recommend you to read the article to better understand this approach. I have used a high-level approach to this concept, and to better utilize this process, the article must be carefully read. This technique can be used in the following manner to simplify a large object hierarchy:

Class clsSiebObjects
	Private m_htContext
 
	'Loads the Object Dictionary
	Public Function Load
		LoadContext
		Set Load = m_htContext
	End Function
 
	'Represents the Object Context
	Private Function LoadContext
		m_Context = CreateObject("Scripting.Dictionary")
 
		'Loading objects in the dictionary.
		With m_Context
			'SiebApplication
			.Add "SiebApplication", SiebApplication("MyApp")
			'SiebScreen (Parent: SiebApplication)
			.Add "SiebScreen", .Item("SiebApplication").SiebScreen("MyScreen")
			'SiebView (Parent: SiebScreen)
			.Add "SiebView", .Item("SiebScreen").SiebView("MySiebView")
			'SiebApplet (Parent: SiebView)
			.Add "SiebApplet", .Item("SiebView").SiebApplet("MySiebApplet")
		End With
	End Function
 
	'Property Get/Let m_Context
	Private Property Let m_Context(ByVal Val)
		Set m_htContext = Val
	End Property
	Private Property Get m_Context()
		Set m_Context = m_htContext
	End Property
End Class

The snippet below shows usage of the above class to simplify Siebel Hierarchy:

Dim oSieb
 
'Instance of the Class
Set oSieb = New clsSiebObjects
Set oSieb = oSieb.Load
 
oSieb.Item("SiebApplet").SiebPickList("lstApplication1").Select "Open"

Summary

In the examples above, you may notice why only the top 4 objects (Application, Screen, View, Applet) of the hierarchy have been included. This is because, including all the objects will really flood your libraries and make spotting the right object quite a cumbersome task. Thus, by including only the top 4 hierarchies, we can simplify our work on a great scale. If the hierarchy changes, we would simply need to modify the elements at one place, only.

For developers wanting to use Descriptive Programming with Siebel Applications, please note that, you will have to write descriptions for your Parent objects only once. When these descriptions change, updating them in a single place will be the only required maintenance. I am using 100% Descriptive Programming with our Siebel application, and the techniques in this article have really simplified a lot of my work by just taking care of the Parent objects.

I hope Automation Developers using Siebel with QTP find this article useful. Thanks for visiting Relevant Codes.

References

Implementing a GUI Layer with Classes by Meir Bar-Tal (AdvancedQTP, SolmarKN).

If you have any questions, please ask them in the comments section. If your information is to be treated as confidential, please use the Contact Form to send me an e-mail instead.

QTP: Working with SiebCalculator

Anshoo Arora — Mon, 10 Aug 2009 21:38:43 +0000

This is the 4th article in the Siebel series. In this article, we will detail an effective way to work with the Siebel Calculator Object.

By default, a Siebel Calculator has a small set of input keys to work with. The idea is to verify that each input key is valid before processing the output through the calculator. The method IsKeyLoaded verifies if the key really exists in the calculator object (all possible keys are hard-coded in the array ‘arrFixedKeys’) whereas the method SiebCalculatorClickKeys presses the keys in an array one after the other.

Usage:

Set oCalc = SiebApplication( "uiname:=MyApp" ).SiebScreen( "uiname:=MyScreen" )_
            .SiebView( "uiname:=MyView" ).SiebApplet( "uiname:=MyApplet" )_
            .SiebCalculator( "uiname:=MyCalculator" )
 
SiebCalculatorClickKeys oCalc, Array( "1", "+", "2", "-", "3", "*", "99" )

The above will simulate (1+2-3*99) in the SiebCalculator object.

How its done:

'————————————————————————————————————————————— 
' Name: Function IsKeyLoaded
' Purpose: Checks if array of keys to be input to Calculator is valid
' Input:
'    arrKeys
' Output: 
'    Boolean
' Date:
' Author: 
' Remarks: 
'————————————————————————————————————————————— 
Private Function IsKeyLoaded( arrKeys )
'————————————————————————————————————————————— 

    Dim arrFixedKeys
    Dim blnExists
    Dim inKey, fixKey
 
    arrFixedKeys = Array( 1, 2, 3, 4, 5, 6, 7, 8, 9, 0, "/", "CE", "*", "C", "-", "%", &_
                     "±", ".", "+", "=" )
 
    For Each inKey in arrKeys
        blnExists = False
        For Each fixKey in arrFixedKeys
            If Trim(LCase(CStr(inKey))) = Trim(LCase(CStr(fixKey))) Then
                blnExists = True
                Exit For
            End If
        Next
        If Not blnExists Then
            IsKeyLoaded = blnExists
            Exit Function
        End If
    Next
 
    IsKeyLoaded = blnExists
 
End Function
 
'————————————————————————————————————————————— 
' Name: Sub SiebCalculatorClickKeys
' Purpose: 
' Input:
'    oCalculator - object reference to the Calculator hierarchy
'    arrKeys - Keys to be pressed on the calculator object
' Output: 
'    Integer
'Dependancy: IsKeyLoaded
' Date:
' Author: 
' Comments: 
'————————————————————————————————————————————— 
Public Sub SiebCalculatorClickKeys( ByVal oCalculator, ByVal arrKeys )
'————————————————————————————————————————————— 

    Dim i
 
    ' Check if the keys entered by the user are valid and exist as keys on the 
    '_ SiebCalculator object.
    isValid = IsKeyLoaded(arrKeys)
 
    ' The following component can be modified to also work with 'ClickKeys':
    '_ enter an array with multiple values in each element and use clickKeys if the length
    '_ is greater than 1, unless if it is the key "CE"
    If Not isValid Then
        Reporter.ReportEvent micWarning, "Invalid Key(s)", "Array: " & Join(arrKeys, ",")
    Else
        'object.OpenPopup
        For i = LBound(arrKeys) to UBound(arrKeys)
            oCalc.ClickKey arrKeys(i)
        Next
        'object.ClosePopup
    End If
 
End Sub

Download this code

When the procedure ends, the output will be visible in the calculator’s output field.

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.

QTP: Working with SiebList

Anshoo Arora — Mon, 10 Aug 2009 21:38:21 +0000

This article has been revised for Siebel Version 8.1. It can be found here

According to Testing Siebel Business Applications at Oracle, “A SiebList object is a singleton container object that is one of the Complex Control Objects. Due to the complex nature of this object, it is also a collection object”. This object can be quite complex to work with, especially when you take into consideration some of the current limitations (I am using Sieb v7.7) found at the KB. Two more limitations can be found in this thread at AdvancedQTP Forums.

Also, when there are many rows present in this object, it may not show the exact number, but instead it shows 1-10+ rows, 11-20+ rows, 21-30+ rows and so on. To get the correct number of rows from the List object, we use an interesting property known as a RecordCounter. A SiebList’s RecordCounter indicates the visible text of the record counter string (for example: 1-10 or 10+).

The idea is to stay in a loop until the “+” sign stops to appear.

Finding the Row Count for SiebList

Option Explicit 'On

'—————————————————————————————————————————
' Name: GetSiebListRows
' 
' Purpose: Get the total number of rows of the List Object without the 
' 1 of 10+, '11 of 20+' and so on..
' 
' Input:
'  oSiebApplet - object reference to the SiebApplet hierarchy
'  pValUINameSiebList - uiname of the SiebList object
' 
' Output: 
'  Integer - number of rows
' 
' Date: 
' 
' Author: 
'—————————————————————————————————————————
Function GetSiebListRows( byRef oSiebApplet, pValUINameSiebList )
'—————————————————————————————————————————
  'SiebList is a list object in a Siebel test automation environment

  Dim vCounter
  If InStr(1, pValUINameSiebList, "uiname") <> 0 Then
    pValUINameSiebList = Trim(Split(pValUINameSiebList, ":=")(1))
  End If
 
  'From QTP Ref:
  '_ The RecordCounter indicates the visible text of the record counter 
  '_ string (for example: 1 - 7 or 7+)
  vCounter = oSiebApplet.RecordCounter
 
  Do
    If InStr(1, vCounter, "+") <> 0 Then
      oSiebApplet.SiebList("uiname:=" & pValUINameSiebList).NextRowSet
      vCounter = oSiebApplet.RecordCounter
    Else
      vCounter = oSiebApplet.RecordCounter
      Exit Do
    End If
  Loop
 
  If InStr(1, vCounter, "of") <> 0 Then
    vCounter = CInt(Trim(Split(CStr(vCounter), "of")(1)))
  End If
 
  GetSiebListRows = vCounter
End Function
 
'* Usage:
' Dim oSiebApplet, intRows
' Set oSiebApplet = SiebApplication("").SiebScreen("").SiebView("").SiebApplet("")
'
' intRows = GetSiebListRows(oSiebApplet, "uiname:=mySiebList")

As I mentioned above, SiebList is quite a complex object. Suppose you have to find some text in one of the columns of the SiebList. Considering the workaround above to find the correct number of rows for the object, we can loop over all the rows until we find the value that we’re looking for.

Note that the column name may be different as it appears to the human eye. You will have to find the correct column name for this to work correctly. For example, in our environment, we have a column named ‘Application Number’. However, ‘Application Number’ is what appears to us, but in reality, QuickTest identifies that column by ‘Application ID’. So, please be a little careful when working with column headings in SiebList.

Finding a text string in a SiebList column

'—————————————————————————————————————————
' Name: Function SiebListFindValRow
' 
' Purpose: Find a row from a column in which a given value (sVal) is located
' 
' Input:
'  oSiebApplet - object reference to the SiebApplet hierarchy
'  pValUINameSiebList - uiname property's value for the SiebList object
'  sColumnName - name of the column where the value is to be found
'  sVal - value that is to be found
' 
' Output: 
'  Integer
' 
'Dependancy: 
'  SiebListRows
' 
' Date:
' 
' Author: 
' 
' Remarks: Make sure the columns name is correct - sometimes the header name
' is not the actual name.
'—————————————————————————————————————————
Function SiebListFindValRow( byRef oSiebApplet, pValUINameSiebList, sColumnName, sVal )
'—————————————————————————————————————————
  'SiebList is a list object in a Siebel test automation environment

  Dim iRows, r, sData, sMsg
 
  If InStr(1, pValUINameSiebList, "uiname") <> 0 Then
    pValUINameSiebList = Trim(Split(pValUINameSiebList, ":=")(1))
  End If
 
  '* Uses GetSiebListRows
  iRows = GetSiebListRows( oSiebApplet, pValUINameSiebList )
 
  oSiebApplet.SiebList("uiname:=" & pValUINameSiebList).FirstRowSet
 
  For r = 0 to iRows - 1
 
    oSiebApplet.SiebList("uiname:=" & pValUINameSiebList).ActivateRow r
    sData = Trim(oSiebApplet.SiebList("uiname:=" & pValUINameSiebList)_
          .GetCellText(sColumnName, r))
 
    If sData = sVal Then
      SiebListFindValRow = r
      sMsg = "The following string: [" & sVal & "] was found in the " & _
            sColumnName & " column of the Siebel List"
      Reporter.ReportEvent micDone, "Siebel List Value found", sMsg
      Exit Function
    End If
 
  Next
 
End Function
 
'* Usage:
' Dim oSiebApplet, intRow
' Set oSiebApplet = SiebApplication("").SiebScreen("").SiebView("").SiebApplet("")
'
' intRow = SiebListFindValRow(oSiebApplet, "uiname:=mySiebList", "Application ID", "Text")

Finding all rows in a column where a text string is found
Now, similar to the requirement above, we may have to find all the rows that carry the text we’re looking for. This can be from 1 to 2 or more rows. This method returns a collection object:

'—————————————————————————————————————————
' Name: Function SiebListFindValAllRows
' 
' Purpose: Find all rows from a given column where a given value exists
' 
' Input:
'  oSiebApplet - object reference to the SiebApplet hierarchy
'  pValUINameSiebList - uiname property's value for the SiebList object
'  sColumnName - name of the column where the value is to be found
'  sVal - value that is to be found
' 
' Output: 
'  Object
' 
'Dependancy: 
'  SiebListRows
' 
' Date:
' 
' Author: 
' 
' Remarks: Make sure the columns name is correct - sometimes the header name is not the actual name.
'—————————————————————————————————————————
Function SiebListFindValAllRows( byRef oSiebApplet, pValUINameSiebList, sColumnName, sVal )
'—————————————————————————————————————————
  'SiebList is a list object in a Siebel test automation environment
  
  Dim iRowsTotal, iRowsRef
  Dim r, i, n, sData, arrArray
 
  Dim oDict: Set oDict = CreateObject( "Scripting.Dictionary" )
 
  If InStr(1, pValUINameSiebList, "uiname") <> 0 Then
    pValUINameSiebList = Trim(Split(pValUINameSiebList, ":=")(1))
  End If
 
  n = 0
 
  'Calls the method: GetSiebListRows (see method above)
  iRowsTotal = GetSiebListRows( oSiebApplet, pValUINameSiebList )
  iRowsRef = CInt(oSiebApplet.SiebList("uiname:=" & pValUINameSiebList).RowsCount)
 
  oSiebApplet.SiebList("uiname:=" & pValUINameSiebList).FirstRowSet
 
  For r = 0 to iRowsTotal - 1
    i = r
    If iRowsRef <= r + 1 Then
      i = iRowsRef - 1
    End If
 
    sData = Trim(oSiebApplet.SiebList("uiname:=" & pValUINameSiebList).GetCellText(sColumnName, i))
 
    If sData = sVal Then
      oDict.Add n+1, r
      n = n + 1
    End If
 
    oSiebApplet.SiebList("uiname:=" & pValUINameSiebList).NextRow
  Next
 
  Set SiebListFindValAllRows = oDict
 
End Function
 
'* Usage:
' Dim oSiebApplet, RowCollection
' Set oSiebApplet = SiebApplication("").SiebScreen("").SiebView("").SiebApplet("")
'
' Set RowCollection = SiebListFindValRow(oSiebApplet, "uiname:=mySiebList", "Application ID", "Text")

Download this code

References

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.

QTP: Working with SiebPickLists

Anshoo Arora — Mon, 10 Aug 2009 21:37:57 +0000

A SiebPickList object closely resembles a List object (WebList) in a Web based environment. A good reference for SiebPickList apart from the QTP help can be found here. Do not confuse a PickList with a SiebList object – they are very different in the way they work, and the latter is much more complex.

In our environment, there are many many SiebPickLists. A good majority of these PickLists are not required fields, but according to the requirements, random values must be selected; ie. the fields cannot be left blank. Since selecting random items in some PickLists does not impact the process, the following can be used to accomplish this task.

Selecting a random value in SiebPickList
The below function can be used to select a random value from the SiebPickList object:

'—————————————————————————————————————————
' Name: Function SiebPickListRandomSelect
' 
' Purpose: Randomly selects an item in a PickList object
' 
' Input:
'  oSiebApplet - object reference to the SiebApplet hierarchy
'  pValUINameSiebPickList - uiname property's value for the SiebList object
' 
' Output
'  Object
' 
' Date:
' 
' Author: Anshoo Arora
' 
' Remarks: 
'—————————————————————————————————————————
Sub SiebPickListRandomSelect( byRef oSiebApplet, pValUINameSiebPickList )
'—————————————————————————————————————————
    'A pick list in a Siebel test automation environment.

    Dim iCnt, i, vNextItemByIndex
 
    If InStr(1, pValUINameSiebPickList, "uiname") <> 0 Then
        pValUINameSiebPickList = Trim(Split(pValUINameSiebPickList, ":=")(1))
    End If
 
    With oSiebApplet.SiebPicklist("uiname:=" & pValUINameSiebPickList)
 
        ' Check if PickList is enabled
        If .IsEnabled Then
            ' Check if PickList is required
            If Not .IsRequired Then
                .Select "#" & RandomNumber.Value(0, .Count - 1)
            Else
                Reporter.ReportEvent micWarning, pValUINameSiebPickList, "Cannot" &_
                " Random Select. Field is Required."
            End If
        Else
            Reporter.ReportEvent micWarning, pValUINameSiebPickList, "Cannot" &_
            " Random Select. Field is disabled."
        End If
 
    End With
 
End Function

Getting all objects of a SiebPickList in a Collection
For required PickLists, I usually check if the item that is to be selected exists before making the selection. Following is how you can retrieve all the items of the PickList in a collection:

'—————————————————————————————————————————
' Name: Function SiebPickListGetAllItems
' 
' Purpose: Retrieve names of all items in a Collection from the PickList object
' 
' Input:
'  oSiebApplet - object reference to the SiebApplet hierarchy
'  pValUINameSiebPickList - uiname property's value for the SiebList object
' 
' Output
'  Collection 
' 
' Dependancy:
'  SiebPickListGetItemsCnt
' 
' Date:
' 
' Author: Anshoo Arora
' 
' Remarks: 
'—————————————————————————————————————————
Function SiebPickListGetAllItems( byRef oSiebApplet, pValUINameSiebPickList )
'—————————————————————————————————————————
    'A pick list in a Siebel test automation environment.

    Dim iCnt, i, vNextItemByIndex
 
    Dim oDict: Set oDict = CreateObject( "Scripting.Dictionary" )
 
    If InStr(1, pValUINameSiebPickList, "uiname") <> 0 Then
        pValUINameSiebPickList = Trim(Split(pValUINameSiebPickList, ":=")(1))
    End If
 
    iCnt = oSiebApplet.SiebPicklist("uiname:=" & pValUINameSiebPickList).Count
 
    For i = 0 to iCnt - 1
        vNextItemByIndex = oSiebApplet.SiebPicklist("uiname:=" & pValUINameSiebPickList).GetItemByIndex(i)
        oDict.Add i+1, vNextItemByIndex
    Next
 
    Set SiebPickListGetAllItems = oDict
 
End Function

The concepts in this article apply strictly to Siebel v7.7

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.

QTP: Working with Siebel – An Introduction

Anshoo Arora — Sun, 09 Aug 2009 22:20:27 +0000

I have now been working with Siebel apps on and off for about 6 months now and I feel that even though there is a great wealth of information available on other technologies, there was very little information available for automating Siebel apps with QTP. I don’t consider myself an expert nor do I feel that the techniques in this and coming articles are ‘best practices’; but, my goal is to share what I did and as always, if you have more efficient ways of performing tasks outlined in any articles here, then I would surely like to hear them!

Introduction

See QTP Reference for:
- Siebel Test Automation-> AutoOn Token
- Siebel Test Automation-> Setting Siebel Record and Run Options
- Siebel Test Automation-> SiebAutomationAccessCode property (optional)
- Siebel Test Automation-> SiebAutomationRequestTimeout property (optional)
See the ‘SetTimeOut’ property of the SiebApplication object (Configure the advanced timeout and access settings specific for the Siebel 7.7 application)
See the ReadMe file for known limitations. Adding to the list of limitations:
- With SiebList, sorting does not work for columns not displayed on the screen. This affects all columns that are accessed using the horizontal slider.
- With SiebList, the columns displayed by the horizontal slider cannot be accessed directly.
Siebel Test Automation data-sheet at Oracle.com contains the latest information on Siebel objects (optional).
Do not load the Web Add-in with the Siebel add-in loaded. The Siebel Add-in accounts for both.

Unlike some other environments, we cannot bypass the parent to reach the child in the object hierarchy. We must create descriptions for each object in the hierarchy if we are using DP. If you record, you will automatically see the entire object hierarchy. Please see the code below for explanation (the page object was not included in the object hierarchy):

''''Web 

'Correct:
1. Browser("title:=Google").Page("title:=Google").WebEdit("name:=q").Set "AdvancedQTP"
'Correct (without the page object defined in the hierarchy):
2. Browser("title:=Google").WebEdit("name:=q").Set "AdvancedQTP"

With Siebel, if an action is to be performed on the SiebList (which is an immediate child of SiebApplet):

''''Siebel

'Correct:
1. SiebApplication("").SiebScreen("").SiebView("").SiebApplet("").SiebList("").Event
 
'Incorrect:
2. SiebApplication("").SiebList("").Event
3a. SiebApplication("").SiebScreen("").SiebApplet("").SiebList("").Event
3b. SiebApplication("").CurrentSiebScreen.SiebApplet("").SiebList("").Event
4a. SiebApplication("").SiebView("").SiebApplet("").SiebList("").Event
4b. SiebApplication("").CurrentSiebView.SiebApplet("").SiebList("").Event

StrictSync
By default, the default wait time for performing an action on any Sieb object is 2 seconds. This is controlled by StrictSync. You can read more about it at HP’s KB, and to increase performance, also set it to 0. Below is how you set the value of StrictSync to 0:

Setting.Packages.WebPackage.Settings("StrictSync") = 0

AutoOn Token
The user must append ‘SWECmd=AutoOn’ to the URL for the Siebel Web Engine to to generate test automation information for the Siebel application. Please see below:

The following URL:
-> http://yourHostName/start.swe?{someLongString}

must be:
-> http://yourHostName/start.swe?SWECmd=AutoOn

Server Configuration
The following 2 entities must be set to ‘True’:

EnableAutomation = TRUE
AllowAnonUsers = TRUE

Siebel Test Automation Overview and Resolutions
[Update Feb 19, 2010: Reported by and Credits to Todd Mescher]: This post at Oracle Blogs also provides numerous resolutions to issues dealt in the Siebel environment.

References

Object Identification Issue with Siebel 8.1

This post is updated often so be sure to check back at a later date.

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.