This article will discuss the concepts of Custom Checkpoints, their benefits, when to use them and how they provide us with greater flexibility in script development. Custom CheckPoints offer an easier and highly flexible way of constructing your object verifications, which is a core concept of test automation. The concepts below, when coupled together can help you build extremely robust scripts, with enough information that your user desires.

Before we begin creating CheckPoints as we would for our application(s), let’s do a quick walk-through of the Reporter Object.

Reporter Object
According to QTP help:

Description: The object used for sending information to the test results.

We use the Reporter object along with its ReportEvent method to send the necessary information to the test results:

ReportEvent: Reports an event to the test results.

Below is the syntax of Reporter.ReportEvent method:

Reporter.ReportEvent EventStatus, ReportStepName, Details [, Reporter]

Possible choices for ReportEvent are:

0 or micPass: Causes the status of this step to be passed and sends the specified message to the report.
1 or micFail: Causes the status of this step to be failed and sends the specified message to the report. When this step runs, the test fails.
2 or micDone: Sends a message to the report without affecting the pass/fail status of the test.
3 or micWarning: Sends a warning message to the report, but does not cause the test to stop running, and does not affect the pass/fail status of the test.

Example:

Reporter.ReportEvent micDone, "Step 1", "Step Done."

I wanted to cover the Reporter object real quick because its a core-concept in creating custom checkpoints. We’ll begin creating them now!

Custom CheckPoints and the Exist Method
This is an extremely important concept, and in my opinion, it should serve as the base to all CheckPoints. It checks whether an object exists on the page or not, and before we can start verifying an object’s properties, it’s important that we check if it is even available to us to perform our verifications. Also, if the object is found in the applicantion, the Exist method returns true, else, it returns false. Syntax:

Object.Exist(Timeout)

In the syntax above, Timeout is the amount of time you would like QTP to wait for the object before it returns a boolean output. Let’s see 2 examples of its use.

1. Case where an object is found:

To check if the Text box exists, we can formulate the following code that will wait for a max of 5 seconds before the WebEdit appears on the page:

MsgBox Browser("title:=.*Relevant Codes.*").Page("micclass:=Page")_
        .WebEdit("name:=txtExistTest").Exist(5)

2. Case where an object is not found.

Let’s use the same example above, and run the same check for the text box below:

MsgBox Browser("title:=.*Relevant Codes.*").Page("micclass:=Page")_
        .WebEdit("name:=txtNotFound").Exist(5) 'False

You may spy on the WebEdit above (just to make sure), and notice that there is actually a textbox with the description we provided. But, still, QuickTest returns a failed status. That is because, for this example, I created 2 such text boxes with the exact same description, so if you just provide the property without an Ordinal Identifier, your code will not work. However still, I feel the above is quite a good example of a scenario that can very well happen in many applications and its a good test of an automation engineer to be cautious from the start.

However, we still haven’t created a CheckPoint yet. A CheckPoint is a conditional method that information the user of an objects’ status during testing. Thus, we must create a conditional method here:

If Browser("title:=.*Relevant.*").WebEdit("name:=txtNotFound").Exist(5)
	Reporter.ReportEvent micPass, "WebEdit CheckPoint", "WebEdit was found. Step Passed."
Else
	Reporter.ReportEvent micFail, "WebEdit CheckPoint", "WebEdit was not found. Step failed."
End If

There you go! You have just created a custom CheckPoint. If you would like to know more about the Reporter object, please use the QTP help, which is an excellent source of information.

Custom CheckPoints and the GetROProperty Method
GetROProperty is short for Get-Runtime-Object-Property. In other words, this method can be used to retrieve the value that the object has, at present. Please note that, in some dynamic applications, runtime object properties can change on various factors. Also, with Descriptive Programming (DP), regardless of what property you retrieve, it will always be a runtime property. Obviously, and I bet you know this, but just to reiterate, all these properties can be viewed from the Object Spy. You can find more information on it in my article Descriptive Programming 1. Below is a snapshot of the TO Properties Tab in Object Spy:

QTP Object Spy TO Properties

You will notice that even though I mentioned RO (RunTime Object) properties, I am looking at the TO (Test Object) tab. This is because, when we use the Object Spy to retrieve an objects’ properties, we are doing it on a runtime object, thus, what we see in the image above are all RunTime object properties with their image in the TO Object properties tab. We will use the GetROProperty method with TO properties.

Also, when writing custom checkpoints, we will (almost) always use RO properties instead of TO properties. That is because, we would like to know what the object contains at present, or at runtime as opposed to what the object contained during record time. However, if you are using Descriptive Programming, regardless of what property you retrieve from your application, it will be a runtime property.

The textbox below should have a value of 10, for the maxLength property. We will create a checkPoint to test that assumption.

If Browser("title:=.*Relevant.*").WebEdit("name:=txtMaxLen").GetROProperty("max length")=10 Then
	Reporter.ReportEvent micPass, "WebEdit MaxLength Text", "Test Passed."
Else
	Reporter.ReportEvent micFail, "WebEdit MaxLength Text", "Test Failed."
End If

Result:

QTP Results

QTP Results

When you open your Test Results after the above statement executes, you will notice that, the test failed. It will always fail because the maxLength for our WebEdit is not 10, but 9. When you you use Object spy to retrieve the max length property, you will notice that it is indeed not 10, but its 9. However, in the real-world, we may not always know the properties these objects will have at runtime, and most of the times you will come to find of errors after your regression suites complete their execution.

Let’s create another CheckPoint, and verify if the Link has the correct color:

Relevant Codes: Test Color

With Browser("title:=.*Relevant Codes.*").Link("text:=Relevant Codes: Test Color")
	If .Exist(5) Then
		If .GetROProperty("color") = "#0000ff" Then
			Reporter.ReportEvent micPass, "RelevantCodes Link", "Correct color."
		Else
			Reporter.ReportEvent micFail, "RelevantCodes Link", "Incorrect color."
		End If
	Else
		Reporter.ReportEvent micFail, "RelevantCodes Link", "Link was not found."
	End If
End With

Result:

QTP Results

QTP Results

CheckPoints for Multiple Objects
There are circumstances where you need to create CheckPoints for multiple objects at once. For instance, if you are creating a Login Function, you may need to create a CheckPoint for the UserName Textbox, Password Textbox and the Submit button. This section of the article details how CheckPoints can be created for multiple objects.

This article shows a way to verify multiple Object Properties through a single Class at once, and reports all Checks in a tabular form to QuickTest Results.

Below, you will see a scenario that I just mentioned above. These objects won’t do anything, but, they show a way you can create CheckPoints to be run for multiple objects together.

With Browser("title:=.*Relevant Codes.*").Page("micclass:=Page")
    If .WebEdit("name:=txtUser").Exist(1) And .WebEdit("name:=txtPassword").Exist(1) Then
        Reporter.ReportEvent micPass, "UserName/Password", "Objects found."
    Else
        Reporter.ReportEvent micFail, "UserName/Password", "Objects not found."
    End If
End With

Multiple Checks - Results

Multiple Checks - Results

Similarly, if we want to verify objects’ properties instead of checking whether they exist, we can do this:

With Browser("title:=.*Relevant Codes.*").Page("micclass:=Page")
    If .WebEdit("name:=txtUser").GetROProperty("max length") = 9 And _
     .WebEdit("name:=txtPassword").GetROProperty("max length") = 9 Then
        Reporter.ReportEvent micPass, "UserName/Password", "Correct MaxLength"
    Else
        Reporter.ReportEvent micFail, "UserName/Password", "Incorrect MaxLength"
    End If
End With

QTP Results

QTP Results

CheckPoints for Hidden Objects
Let’s create another CheckPoint. This time, things will get a little complex. Below you will see a Textbox, but indeed there are 2. One of them is hidden. Is there a way to know that one of these Text boxes is hidden? The answer is: Yes.

With Browser("title:=.*Relevant Codes.*")
'If the first text box, that is, the text box with index 0 is hidden then.. set value in Text Box #2
    If .WebEdit("name:=txtIsVisible", "index:=0").GetROProperty("visible") = False Then
        Browser("title:=.*Relevant Codes.*").WebEdit("name:=txtIsVisible", "index:=1").Set "2nd"
    Else
        'Else, set value in Text Box #1
        Browser("title:=.*Relevant Codes.*").WebEdit("name:=txtIsVisible", "index:=0").Set "1st"
    End If
End With

In practice, many people make the mistake of omitting an ordinal identifier in such cases. When you run the same code without an ordinal identifier:

'Error
MsgBox Browser("title:=.*Relevant Codes.*").WebEdit("name:=txtIsVisible").GetROProperty("visible")

You can generally run the following bit of code to find out which object is hidden:

Set oDesc = Description.Create
oDesc("name").value = "txtIsVisible"
 
Set colObject = Browser("title:=.*Relevant Codes.*").Page("micclass:=Page").ChildObjects(oDesc)
 
For x = 0 to colObject.Count - 1
	Print "Object " & x & ": " & colObject(x).GetROProperty("visible")
Next

In your print log, you will have the following information:

'Object with Index = 0 is Hidden
Object 0: False

'Object with Index = 1 is not Hidden
Object 1: True

There are more ways to hide objects, and there are several techniques that can be used to spot them. However, I will let my readers explore those scenarios and find the many possibilities available to them.

I hope this article clarifies some doubts, and gives you more confidence using them in your everyday development.

References
1. QuickTest Professional Help

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.

.

photo credit: h.koppdelaney

This article is a follow-up to the Descriptive Programming Series and will discuss a simple way of creating Object Descriptions on the fly. There are several reasons for using this approach, such as overcoming the need to write extra code and having the ability to make the change in only a single place while performing maintenance. This article includes the concepts and working examples of how and when we can must use this approach.

There are instances where object descriptions are incremented in a numerical context. In other words, a part of the object description stays the same, but these descriptions increment starting at a number, generally 0.

To illustrate, consider the below HTML_IDs for 4 list boxes in a Web Application:

List Box 1 HTML ID -> lstBox0
List Box 1 HTML ID -> lstBox1
List Box 1 HTML ID -> lstBox2
List Box 1 HTML ID -> lstBox3

Notice how the descriptions above increment. lstBox is common in all 4 descriptions, but there is a numerical increment after each, starting at 0. When creating an object description in such a scenario, you may tend to do the following:

Browser("SomeBrowser").Page("SomePage").WebList("html id:=lstBox0").Select "Item"
Browser("SomeBrowser").Page("SomePage").WebList("html id:=lstBox1").Select "Item"
Browser("SomeBrowser").Page("SomePage").WebList("html id:=lstBox2").Select "Item"
Browser("SomeBrowser").Page("SomePage").WebList("html id:=lstBox3").Select "Item"

The above is a common usage, and completely acceptable. But in practice, we may have more than 4 Objects with such descriptions and creating the same line of code over and over again, and maintaining everything can be quite a task. In such situations, the concept in this article can be quite beneficial. For example, the above code snippet can be condensed into:

'use a variable to increment from 0 to 3
For x = 0 to 3
	Browser("SomeBrowser").Page("SomePage").WebList("html id:=lstBox" & x).Select "Item"
Next

Now, if the HTML_ID of this object changes, we have to make the change only once as opposed to several times. For example, if the HTML_ID of the list box above was to change from lstBox to lstObject, we would simply update our code like this:

For x = 1 to 4
	'lstBox becomes lstObject
	Browser("SomeBrowser").Page("SomePage").WebList("html id:=lstObject" & x).Select "Item"
Next

Instead of updating it 4 times:

Browser("SomeBrowser").Page("SomePage").WebList("html id:=lstObject0").Select "Item"
Browser("SomeBrowser").Page("SomePage").WebList("html id:=lstObject1").Select "Item"
Browser("SomeBrowser").Page("SomePage").WebList("html id:=lstObject2").Select "Item"
Browser("SomeBrowser").Page("SomePage").WebList("html id:=lstObject3").Select "Item"

Numeric Increments
Let’s see a working example. Please open a new IE browser and navigate to the following Page: Demo 1. You can simply set values in all of the text boxes using the following snippet:

With Browser("name:=SimpleDemo1.*").Page("micclass:=Page")
	For x = 1 to 6
		.WebEdit("html id:=txtDemo" & x ).Set "Text Box " & x
	Next
End With

Alphabetic Increments
Now imagine a similar situation where numeric increments are replaced with alphabets. There are several ways of working with such scenarios, but what I generally do is create an array with all the alphabets and increment elements of that array to work with runtime objects:

Dim arrAlphabets: ReDim arrAlphabets(25)
 
arrAlphabets = Array("a", "b", "c", "d", "e", "f", "g", "h", _
		"i", "j", "k", "l", "m", "n", "o", "p", "q", "r", _
		"s", "t", "u", "v", "w", "x", "y", "z")

Now, we can use the array of alphabets using the exact same approach we used for numeric descriptions on Demo Page 2.

With Browser("name:=SimpleDemo2.*").Page("micclass:=Page")
    For x = 1 to 6
        .WebEdit("html id:=txtDemo_" & arrAlphabets(x-1)).Set "Text Box " & UCase(arrAlphabets(x-1))
    Next
End With

If you are starting off with Descriptive Programming and VBScript Arrays, and would like to learn how the above approach works, please ask your questions in the comments section and I will try my best to help you.

Complex Increments
The above 2 uses of this technique are quite basic, and chances are that in your environment, you may not see such simple instances. Let’s create another scenario then, with a little complex description. Please open a new browser, and navigate to Demo Page 3.

When you spy on the WebEdits on this page, you will see a long description for the ‘name’ property. The name property of the six WebEdits are:

txt_applicant[0]BuyProductBox_answerString_A
txt_applicant[1]BuyProductItem_answerString_B
txt_applicant[2]BuyProductBall_answerString_C
txt_applicant[3]BuyProductBat_answerString_D
txt_applicant[4]BuyProductSpoon_answerString_E
txt_applicant[5]BuyProductFork_answerString_F

How can the description for this object be created such that, we can get our work done through a single line of code, instead of creating 6 different statements to set a value in each text box? Notice the descriptions closely, not only are the applicant numbers incrementing in numerical and alphabetical context, but the product lines are changing as well (Box, Item, Ball etc).

The trick here is to use RegularExpressions/WildCards to make the description generic so it becomes available to all 6 WebEdits. There are several ways this generic description can be created, and if you solved this using a different description, please feel free to share it.

Below is one possible solution for our complex scenario:

Dim arrAlphabets: ReDim arrAlphabets(25)
Dim sName
 
arrAlphabets = Array("a", "b", "c", "d", "e", "f", "g", "h", _
		"i", "j", "k", "l", "m", "n", "o", "p", "q", "r", _
		"s", "t", "u", "v", "w", "x", "y", "z")
 
With Browser("name:=SimpleDemo3.*").Page("micclass:=Page")
    For x = 0 to 5
        sName = "txt_applicant\[" & x & "\].*_" & arrAlphabets(x)
        .WebEdit("name:=" & sName).Set "Text Box " & UCase(arrAlphabets(x))
    Next
End With

Summary
This article summarized how working with objects with similar descriptions can be achieved in a simple manner. This approach may not be feasible for all environments, and should only be used when possible. You’re most likely to see Approach#3 in this article used most often, and at times, it does get a little tricky to write descriptions to work with all objects having similar properties.

This article is the last in the Introductory DP series, and future articles will cover advanced concepts and techniques of working with real-life applications.

I hope you guys find this article useful. Thanks for reading :)

If you have any questions, please ask them in the comments section. If your information is to be treated as confidential, please use the Contact Form to send me an e-mail instead.

photo credit: SideLong

Introduction
In this article, we will cover the basics of Description Object and the ChildObjects method. This is a very powerful approach to creating robust automation test suites. It is also a very important principle of Descriptive Programming in QTP.

We will see how we can create an object description with a single property, with multiple properties, by using regular expressions and finally putting all these concepts into their application with the ChildObjects method.

Before we see how it is done, we must first understand the following statement:

Set oDesc = Description.Create

Above, we are using the variable oDesc to create a description of something. Since, oDesc is preceeded by a Set statement, it must be an object reference. Therefore, when the above statement executes, oDesc will become an object reference to a description object. We will use the description object with the ChildObjects method to retrieve object collections. These object collections are nothing but arrays of objects with the exact properties of the description object.

If you are starting with DP, please read the article on Descriptive Programming Concepts on Relevant Codes for a quick walk-through on Descriptive Programming before continuing with this article.

I. Creating a Description Object for a Parent (Browser/Window)
To create an object description for a parent, we will simply use the “Class” of the parent object and add the property-value combination:

Dim oDesc        'Description Object
Dim colObject    'Object Collection

Set oDesc = Description.Create
'Remember to always use 'micclass' and not 'class name'
oDesc( "micclass" ).value = "Browser"
 
'We used Desktop as the parent here because, the Desktop Object holds all the Windows
Set colObject = Desktop.ChildObjects( oDesc )

When the above snippet execute, colObject will contain a collection of all browsers visible on the desktop.

But, since we have done this, how will we know how many browser objects exist on the desktop through code? Also, how will we retrieve their information? The answer is quite simple: colObject contains the necessary information and methods we can use to perform events on our target objects.

'Retrieve # of open browsers
MsgBox colObject.Count
 
'Retrieve Titles of all open browsers
For x = 0 to colObject.Count - 1
	MsgBox colObject(x).GetROProperty("title")
Next

As I mentioned above, colObject is nothing but an array of all objects having the exact same properties as the description object. Therefore, colObject(0) points to the first object in the collection, colObject(1) points to the second object in the collection, and so on. This is demonstrated in the For..Next loop in the snippet above.

II. Creating a Description Object for an Object contained in a Browser/Window
Using the same approach above, we will retrieve collection of all Link objects on a page. Notice here that instead of Desktop, we have used the entire Browser-Page hierarchy. This is because, a link object is present somewhere inside the Page, instead of the desktop :).

Dim oDesc        'Description Object
Dim colObject    'Object Collection

Set oDesc = Description.Create
oDesc( "micclass" ).value = "Link"
 
'Using the entire Browser-Page hierarchy
Set colObject = Browser( "title:=Google").Page("title:=Google").ChildObjects( oDesc )

By executing the snippet above, we will use colObject to perform some events on these objects. Let’s retrieve the number of link objects present in our browser:

'Returns 30
MsgBox colObject.Count

The above example is created for the Google page, and if you want to test it for some other browser, do not forget to change the Browser and Page titles to the correct values.

III. Creating a Description Object for an Object contained in a Browser/Window Using Multiple Properties
If you saw the above example, we created a description object using only the class of the Link object. Now, we will retrieve a more specific object collection. We are going to specify an additional property and narrow down the search results- this is because, even though there can be multiple Link objects on a page, its not necessary that there would be the same number of objects with the text “Hello, I am a Link!”.

This approach helps us retrieve only the objects that we really want for our automation, since having a collection of all objects can be quite cumbersome to work with. Also, if we provide relevant information to our Description Object, QTP will return a narrowed-down collection, which is the easiest to work with. This is similar to how you search Google. If you specify “QTP” in Google Search, you will have a huge array of search results. You can narrow down the search results (and find information faster) if you add “QTP + Browser + DP” instead.

Dim oDesc        'Description Object
Dim colObject    'Object Collection

Set oDesc = Description.Create
oDesc( "micclass" ).value = "Link"
'Additional property- for more focused and controlled collection
oDesc( "text" ).value = "Images"
 
Set colObject = Browser( "title:=Google").Page("title:=Google").ChildObjects( oDesc )
 
Msgbox colObject.Count    'Returns 1

Now, colObject will only contain the Link objects that have the text: Images. Also, if you notice Google page, there is only one link with the Images text. This is a good example of finding the target object dynamically. Suppose, if there were 2 links on the page instead, we would have both of them in our collection colObject. Let’s highlight our found object:

colObject(0).Highlight

Executing the statement above, we will highlight the first object in the collection. I know there is only one object in the collection, but we can make sure by doing this:

For x = 0 to colObject.Count - 1
	colObject(x).Highlight
Next

IV. Creating a Description Object using WildCards
If we have dynamic objects in our application, then we may not always have the luxury to feed their properties as we have done in the example above. Sometimes, we would need to create dynamic descriptions and retrieve our target objects from resulting (dynamic) collections. I say dynamic collections because at one time, your collection may hold 9 objects, whereas during the next session, it may hold 10.

Dim oDesc        'Description Object
Dim colObject    'Object Collection

Set oDesc = Description.Create
oDesc( "micclass" ).value = "Link"
oDesc( "text" ).value = "I.*age.*"  'Images
'.regularExpression is 'True' by default
oDesc( "text" ).regularExpression = True
 
Set colObject = Browser( "title:=Google").Page("title:=Google").ChildObjects( oDesc )

You may want to read the article on Regular Expressions to better understand how these work in Descriptive Programming.

After executing the snippet above, we will have a collection object with all object that match the regular expression. Let’s see the count of the objects:

'Returns 1 because our supplied pattern only matches with the word: Images
MsgBox colObject.Count

Let’s replace the “text” with “ma” instead and see if we still retrieve a collection with a single object:

Dim oDesc        'Description Object
Dim colObject    'Object Collection

Set oDesc = Description.Create
oDesc( "micclass" ).value = "Link"
oDesc( "text" ).value = ".*ma.*"  'Images
'.regularExpression is 'True' by default
oDesc( "text" ).regularExpression = True
 
Set colObject = Browser( "title:=Google").Page("title:=Google").ChildObjects( oDesc )

To see what has changed, let’s execute the following:

'Will return 4
MsgBox colObject.Count

If you do execute the snippet above, the count would be 4. Why is that? To see the new objects in our collection, let’s do this:

For x = 0 to colObject.Count - 1
	MsgBox "x:" & x & " || " & colObject(x).GetROProperty("innertext")
Next

Below are our outputs:

Interesting, isn’t it? Our description for the text property matched all links that had the letters ma in them.

V. Negating WildCards
Sometimes we have an object description with wildcards in it. Here, we want to turn off the Description Object’s ability to register the description as a regular expression. This is quite simple, and we do it by turning regular expression as False:

Dim oDesc        'Description Object
Dim colObject    'Object Collection

Set oDesc = Description.Create
oDesc( "micclass" ).value = "Link"
oDesc( "text" ).value = ".*ma.*"  'Images
oDesc( "text" ).regularExpression = False
 
Set colObject = Browser( "title:=Google").Page("title:=Google").ChildObjects( oDesc )
 
MsgBox colObject.Count    'Returns 0

Now, the above snippet will not identify Images or Maps. Instead, it will only identify objects that have the exact text .*ma.* which really doesn’t exist anywhere on the Google homepage.

VI. Creating a Description Object for Integer-Types
So far, we have only learned various ways to work with description objects using Strings. Here, we will see how they transform into integer-types. Let’s bring up the properties of the Images link again using the Object spy and feed its “x” coordinate to see whether we can find the link:

Object Spy Snapshot: Images Link (Google)

Dim oDesc        'Description Object
Dim colObject    'Object Collection

Set oDesc = Description.Create
oDesc( "micclass" ).value = "Link"
oDesc( "x" ).value = 51             'It should always be 51, not "51".

Set colObject = Browser( "title:=Google").Page("title:=Google").ChildObjects( oDesc )
 
'Will return 1
MsgBox colObject.Count
 
'Will return Images
For x = 0 to colObject.Count - 1
	MsgBox colObject(x).GetROProperty("innertext")
Next

Notice that 51 above is not within quotation marks. This should always be the case. Notice when we replace it with a string-type below:

Dim oDesc        'Description Object
Dim colObject    'Object Collection

Set oDesc = Description.Create
oDesc( "micclass" ).value = "Link"
oDesc( "x" ).value = "51"
 
Set colObject = Browser( "title:=Google").Page("title:=Google").ChildObjects( oDesc )
 
MsgBox colObject.Count
 
For x = 0 to colObject.Count - 1
	MsgBox colObject(x).GetROProperty("innertext")
Next

The collection is an empty one:

(Mis)Using Integers as Strings

So, always remember to treat integers as they are. This always holds true for x, y, abs_x, abs_y.

VII. Building Object hierarchy with ChildObjects
We will use the Browser Object Collection to set a value in a text box to demonstrate this:

Dim oDesc        'Description Object
Dim colObject    'Object Collection

Set oDesc = Description.Create
oDesc( "micclass" ).value = "Browser"
oDesc( "title" ).value = "Google"
 
'Notice we used the Desktop Object again for retrieving Window collection
Set colObject = Desktop.ChildObjects( oDesc )
 
'Retrieve the count
iCount = colObject.Count
 
'Set value in the WebEdit of the last Window object in the collection
For x = 0 to iCount - 1
   'Verify if the Browser title equals "Google"
   If Browser("creationtime:=" & x).GetROProperty("title") = "Google" Then
      'Set Description.Create in the search TextBox
      Browser("creationtime:="&x).Page("micclass:=Page").WebEdit("name:=q").Set "Description.Create"
   End If
Next

When the above snippet executes, we will have the following value set in the Search TextBox in Google HomePage:

Using Description.Create to Set Value

I hope this article will help you guys understand the concepts of one of the most important concepts in Descriptive Programming: the Description Object. Thanks for visiting Relevant Codes :)

If you have any questions, please ask them in the comments section. If your information is to be treated as confidential, please use the Contact Form to send me an e-mail instead.

photo credit: Francisco Javier Martín

This is the last article in our Descriptive Programming series and will cover a simple login process using 100% DP. I have purposely created the example to be very high-level to make sure its quit easy to understand. However, if you feel more examples on this concept will help, I’ll be more than happy to create a Part V of this series with only real-world examples of DP in action.

We will use the HP/Mercury Demo Website for this example.

Following is the process I am going to follow to complete this process. In your application however, you can use the process that best suits your needs, but for the purposes of this lesson, I will keep it quite basic:

1. Launch Browser.
2. Check whether the correct browser opened.
3. Ensure the userName, password edits and the Sign-In button exist.
4. Set the userName and password and Click Sign-In.
5. Make sure the browser navigated to the correct page.

Step 1: Launch Browser

'We will use SystemUtil.Run to launch our target browser
SystemUtil.Run "iexplore.exe", "http://newtours.demoaut.com/"

Step 2: Checking if the correct browser opened

The 2 new concepts in this step are:

1. Reporter Object: This object is used to send individual reports to the test results. In other words, when the test ends, you can see the reported events in your Test results.
2. ExitTest: A utility statement available to QTP that enables it to complete exit a Test. In other words, when this statement executes, the test execution ends.

If Browser( "title:=Welcome: Mercury Tours" ).Exist( 15 ) Then
   Reporter.ReportEvent micPass, "Step 1- Launch", "Correct browser was launched."
Else
   Reporter.ReportEvent micFail, "Step 1- Launch", "Browser failed to launch."
   ExitTest
End If

Step 3: Ensure the userName, password edits and the Sign-In button exist.

'Notice the use of the wildcard character below
If Browser("title:=Welcome:.*").Page("title:=Welcome.*").WebEdit("name:=userName").Exist(0) Then
   'set username
   If Browser("title:=Welcome:.*").Page("title:=Welcome.*").WebEdit("name:=password").Exist(0) Then
      'set password
      If Browser("title:=Welcome:.*").Page("title:=Welcome.*").Image("name:=login" ).Exist(0) Then
         'click button
      Else
         'report that Sign-In button was not found
      End If
   Else
      'report that the password edit was not found
   End If
Else
   'report that the userName edit was not found
End If

Step 4: Set the userName and password and Click Sign-In.

The following will complete the snippet above:

'Notice the use of the wildcard character below
With Browser("title:=Welcome:.*").Page("title:=Welcome.*")
   If .WebEdit("name:=userName").Exist(0) Then
      .WebEdit("name:=userName").Set "test"
      If .WebEdit("name:=password").Exist(0) Then
         .WebEdit("name:=password").Set "test"
         If .Image("name:=login" ).Exist(0) Then
            .Image("name:=login" ).Click
         Else
            Reporter.ReportEvent micFail, "Sign-In Button Error", "Button not found."
         End If
      Else
         Reporter.ReportEvent micFail, "Password Edit Error", "EditBox not found."
      End If
   Else
      Reporter.ReportEvent micFail, "UserName Edit Error", "EditBox not found."
   End If
End With

Step 5: Make sure the browser navigated to the correct page

'Synchronize with a browser
Browser( "title:=.*" ).Sync
 
'Wait 1 second for browser with "Find a Flight" title to exist
If Browser( "title:=Find a Flight.*" ).Exist( 1 ) Then
   Reporter.ReportEvent micPass, "Login", "Login successful"
Else
   Reporter.ReportEvent micFail, "Login", "Login failed"
End If

Putting it all together

'We will use SystemUtil.Run to launch our target browser
SystemUtil.Run "iexplore.exe", "http://newtours.demoaut.com/"
 
If Browser( "title:=Welcome: Mercury Tours" ).Exist( 15 ) Then
   Reporter.ReportEvent micPass, "Step 1- Launch", "Correct browser was launched."
Else
   Reporter.ReportEvent micFail, "Step 1- Launch", "Browser failed to launch."
   ExitTest
End If
 
'Notice the use of the wildcard character below
With Browser("title:=Welcome:.*").Page("title:=Welcome.*")
   If .WebEdit("name:=userName").Exist(0) Then
      .WebEdit("name:=userName").Set "test"
      If .WebEdit("name:=password").Exist(0) Then
         .WebEdit("name:=password").Set "test"
         If .Image("name:=login").Exist(0) Then
            .Image("name:=login").Click
         Else
            Reporter.ReportEvent micFail, "Sign-In Button Error", "Button not found."
         End If
      Else
         Reporter.ReportEvent micFail, "Password Edit Error", "EditBox not found."
      End If
   Else
      Reporter.ReportEvent micFail, "UserName Edit Error", "EditBox not found."
   End If
End With
 
Browser( "title:=.*Mercury.*" ).Sync
 
If Browser( "title:=Find a Flight.*" ).Exist( 1 ) Then
   Reporter.ReportEvent micPass, "Login", "Login successful"
Else
   Reporter.ReportEvent micFail, "Login", "Login failed"
End If

If you have any doubt in the content above, please feel free to post a comment about it. I hope this article helps understand further the principles of Descriptive Programming and using it in your everyday work.

Descriptive Programming Series

1. Descriptive Programming (DP) Concepts – 1
2. Descriptive Programming (DP) Concepts – 2 {Regular Expressions}
3. Descriptive Programming (DP) Concepts – 3 {Ordinal Identifiers}
4. Descriptive Programming (DP) – 4 {Creating a Test Script)

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.

This is the third article in the Descriptive Programming series, and will outline the concepts of Ordinal Identifiers used in QTP. We will also create a simple test module (step by step) for a login process using only Descriptive Programming (DP).

Ordinal Identifiers – What are they?

Let me quote QTP Reference here:

An ordinal identifier assigns a numerical value to a test object that indicates its order or location relative to other objects with an otherwise identical description (objects that have the same values for all properties). This ordered value provides a backup mechanism that enables QuickTest to create a unique description to recognize an object when the defined properties are not sufficient to do so.

Let’s break the above definition from Mercury/HP into several parts to clarify the concept.

An ordinal identifier assigns a numerical value to a test object

From the quote above, we can conclude that an ordinal identifier is a numerical entity. In other words, its simply a number that is assigned to a test object.

that indicates its order or location relative to other objects with an otherwise identical description (objects that have the same values for all properties)

This means, an Ordinal Identifier works quite differently in relation to the properties we learned in the 1st part of this series. This identifier, or a property if you will, works according to the order or location of test objects. Objects’ order and location are unique characteristics. For example, in a coordinate system, generally only a single object exists on a given ‘x,y’ coordinate. Thus, an ordinal identifier will always be unique. Index defines the order, and location defines location.

This ordered value provides a backup mechanism that enables QuickTest to create a unique description to recognize an object when the defined properties are not sufficient to do so.

The quote above is a good way to conclude this concept of Ordinal Identifiers in QTP. Since it is always unique for an object, it can become extremely useful including these with objects’ mandatory and assisstive properties to prevent falling into object recognition problems. The 3 types of ordinal identifiers are: Location, Index and CreationTime (browser only).

Location Ordinal Identifier

Let’s use an example to understand how the Location Identifier works. Consider the 4 WebEdits below:

All the edits above have exactly the same properties. This property works vertically, from top to bottom, and left to right. Thus, ‘Text Box 1‘ will have a location value of 0, ‘Text Box 3‘ will have 1, ‘Text Box 2‘ will have 2, and ‘Text Box 4‘ will have 3. Note that VBScript is zero based, so the location property would start at 0. This can be verified by running the following statements:

'Text Box 1
Browser("title:=.*Descriptive.*").Page("micclass:=Page").WebEdit("name:=dpTest","location:=0").Set "1"
 
'Text Box 3
Browser("title:=.*Descriptive.*").Page("micclass:=Page").WebEdit("name:=dpTest","location:=1").Set "2"
 
'Text Box 2
Browser("title:=.*Descriptive.*").Page("micclass:=Page").WebEdit("name:=dpTest","location:=2").Set "3"
 
'Text Box 4
Browser("title:=.*Descriptive.*").Page("micclass:=Page").WebEdit("name:=dpTest","location:=3").Set "4"

Text Box 1: location=0
Text Box 2: location=2
Text Box 3: location=1
Text Box 4: location=3

Index Ordinal Identifier

Index is quite similar to location, but it works pertaining to appearance of objects in the source code¹. An object appearing prior in the source code will have a smaller Index value as compared to another object that comes later in the source. Thus, for the same group of edit boxes above: ‘Text Box 1′ will have an index of 0, ‘Text Box 2′ will have 1, ‘Text Box 3′ will have 2 and ‘Text Box 4′ will have 3. Let’s test our statements:

'Text Box 1
Browser("title:=.*Descriptive.*").Page("micclass:=Page").WebEdit("name:=dpTest", "index:=0").Set "1"
 
'Text Box 2
Browser("title:=.*Descriptive.*").Page("micclass:=Page").WebEdit("name:=dpTest", "index:=1").Set "2"
 
'Text Box 3
Browser("title:=.*Descriptive.*").Page("micclass:=Page").WebEdit("name:=dpTest", "index:=2").Set "3"
 
'Text Box 4
Browser("title:=.*Descriptive.*").Page("micclass:=Page").WebEdit("name:=dpTest", "index:=3").Set "4"

Text Box 1: index=0
Text Box 2: index=1
Text Box 3: index=2
Text Box 4: index=3

That was quite easy, wasn’t it? Now, let’s move on to CreationTime, which is an ordinal identifier strictly reserved for the browser object.

CreationTime Ordinal Identifier

Again, let’s use the description given by HP/Mercury in QTP’s helpfile:

If there are several open browsers, the one with the lowest CreationTime is the first one that was opened and the one with the highest CreationTime is the last one that was opened.

That means, the first browser you open will have a creationtime of 0. The second browser will have a creationtime of 1. The third browser will have a creationtime of 2 and so on.

SystemUtil.Run "iexplore.exe", "http://www.HP.com"               'CreationTime 0
SystemUtil.Run "iexplore.exe", "http://www.AdvancedQTP.com"      'CreationTime 1
SystemUtil.Run "iexplore.exe", "http://www.LinkedIn.com"         'CreationTime 2

Browser( "creationtime:=" ).Highlight     'Highlight HP.com
Browser( "creationtime:=1" ).Highlight    'Highlight AdvancedQTP.com
Browser( "creationtime:=2" ).Highlight    'Highlight LinkedIn.com

When you run the above code in QTP, you will find that the first browser QTP highlights on is HP.com, the second is AdvancedQTP.com and the third is LinkedIn.com. Even this is quite simple, isn’t it?

As promised, we must create a simple login process using the concepts we have learned so far in the next article.

Descriptive Programming Series

1. Descriptive Programming (DP) Concepts – 1
2. Descriptive Programming (DP) Concepts – 2 {Regular Expressions}
3. Descriptive Programming (DP) Concepts – 3 {Ordinal Identifiers}
4. Descriptive Programming (DP) – 4 {Creating a Test Script)

^1. Credits go to Harish for finding this error. Thank you Harish!!

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.

photo credit: dkalo

DP vs OR: Which is better?

This has been a never ending debate and if you follow QTP forums, you will see a thread pop-up every few days. Most commonly, the OP is trying to inquire which one would be better (vague?), which one would require less maintenance time, which one is more user-friendly, which has the performance upside, which one will my boss admire more etc.

The answer isn’t simple.

That’s why this has been a never ending debate :)

I do not guarantee that after reading this post, you will have an answer, but I am sure with some planning, you will be able to make up your mind as to which one would be the better alternative in the long run.

1. In Expert View, DP and OR statements are written in the following manner:

'OR
Browser( "Google" ).Page( "Google" ).WebEdit( "q" ).Set "Google Search"
 
'DP
Browser( "title:=Google" ).Page( "title:=Google" ).WebEdit( "name:=q" ).Set "Google Search"

With DP, the properties are written with their corresponding values. OR, on the other hand, shows only a logical description of the object.

2. A DP parent will only recognize a child that has DP style layout. In other words, you CANNOT add a child to a DP parent that has its properties stored in the OR. Example:

'Will not work: Browser is DP whereas Page and WebEdit are OR
Browser( "title:=Google" ).Page( "Google" ).WebEdit( "q" ).Set "Google Search"
 
'Will not work: Browser and Page are DP whereas WebEdit is OR
Browser( "title:=Google" ).Page( "title:=Google" ).WebEdit( "q" ).Set "Google Search"

However, an OR parent will recognize both OR and DP style children:

'Will work: Browser is OR whereas Page and WebEdit are DP
Browser( "Google" ).Page( "title:=Google" ).WebEdit( "name:=q" ).Set "Google Search"
 
'Will work: Browser and Page are OR whereas WebEdit is DP
Browser( "Google" ).Page( "Google" ).WebEdit( "name:=q" ).Set "Google Search"

3. Writing good DP for Objects takes experience and skill. Even though DP has become extremely popular, improperly written DP can lead to performance issues, maintenance headaches etc. Its quite a different story with OR where you record the objects and QTP creates the hierarchy.

4. The user must be careful when using DP: it is case sensitive (except in the case of Web Applications). Do not confuse this with how VBScript works. If the value of a property ‘html id’ is ‘txtZip’ then it must be coded as ‘txtZip’, not ‘txtzip’ or ‘TXTZIP’. QTP will only find the object if the value is written exactly as in the Object Spy. Example (WebEdit’s name property is retrieved as ‘editNewName’):

'Correct description for WebEdit
Window("nativeclass:=Test").WinEdit( "name:=editNewName" ).Set "DP"
 
'Incorrect description for WebEdit
Window("nativeclass:=Test").WinEdit( "name:=editnewname" ).Set "DP"
 
'Incorrect description for WebEdit
Window("nativeclass:=Test").WinEdit( "name:=EDITNEWNAME").Set "DP"

5.Unlike OR, DP does not have auto-complete. All object descriptions must be coded out manually. This can be quite time consuming, and even frustrating for people who’re used to working with OR.

Object Repository Auto Complete Feature

6.Unlike OR’s ‘Highlight in Application’ feature, when searching for an object hierarchy written in DP, you must execute the line of code to locate the object in the application. Another way would be to keep a record of all objects, which can be quite tedious.

Object Repository Highlight in Application Feature

7. DP supports ChildObjects (to create the description object, you MUST use DP). Description object example:

Dim oDesc
 
Set oDesc = Description.Create
'Add a name property to the description
oDesc( "name" ).Value = "q"
'Add a html tag property to the description
oDesc( "html tag" ).Value = "INPUT"

8. On average, DP is slower than OR (note: on average!). With DP, QTP creates the an object from the provided hierarchy of DP and locates the object in the application before performing an event. Demo:

'OR: 9.74 seconds
For i = 0 to 99
	Browser("Google").Page("Google").WebEdit("q").Set "QTP"
Next
 
'DP: 14.64 seconds
For i = 0 to 99
	Browser("title:=Google").Page("title:=Google").WebEdit("name:=q").Set "QTP"
Next

9. OR has a GUI which makes is easy to understand object hierarchies and maintain objects. DP hierarchies are code statements. Example:

Object Repository Front End GUI

WhiteBox style DP

10. .Object is available to both DP and OR:

'OR
Browser("Google").Page("Google").WebEdit("q").Object.Value = "QTP"
 
'DP
Browser("title:=Google").Page("title:=Google").WebEdit("name:=q").Object.Value = "QTP"

11. Objects have logical names in OR which makes it easy to identify them. Sadly, DP doesn’t, since its based on principles of a white-box.

12. This is strictly for OR, but at times you will notice that when working with applications, objects are added as: WebEdit_1, WebEdit_2, WebEdit_3 … WebEdit_n and so on. This can be extremely cumbersome to deal with, and it takes quite long to rename all the objects in OR to give them meaningful names.

13. Code written with DP can be easily copied/pasted onto other scripts or functions. With OR based scripts, a simple copy/paste will not result in a working script. All the repositories (local/shared) would have to be associated with the test to make it executable. Therefore, when creating test with many reusable components, its generally easier to work with DP in comparison to OR unless there is a comprehensive use of Shared Object Repositories [Credits: Yogindernath.

14. Object Repositories have capabilities to perform single-point maintenance, whereas with DP, during changes, all objects undergo manual updates. In situations where there are several changes in the AUT, OR can prove to be a better performer [Credits: Marc Miedemo].

If you feel I have missed something and must be added or corrected, please post a comment and I will update this post, giving full credit to you. Thanks :)

References
1. Connected Testing

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.

A wildcard character can be used to substitute for any other character or characters in a string.¹ This means, we can use a wildcard to make our descriptions more generic. For example, if the property ‘file name’ of an Image is ‘getAllAttributes.JPG’, we can use a wildcard several ways:

' Only using the first 2 words: getAll
Browser( "title:=MyTitle" ).Page( "title:=MyTitle" ).Image( "file name:=getAll.*" ).Click
' Using 1 word (Attributes) with the extension (JPG)
Browser( "title:=MyTitle" ).Page( "title:=MyTitle" ).Image( "file name:=.*Attributes.*JPG" ).Click

Let’s put this technique into practice. Let’s use Mercury Tours for this test. Let’s try to identify the banner image (banner2.gif) having the following text embed: ‘one cool summer ARUBA’.

This image is the property of http://newtours.demoaut.com (HP/Mercury)

Browser("title:=Welcome: Mercury Tours").Page("title:=Welcome: Mercury Tours").Image("file name:=banner2.gif").Highlight
 
Browser("title:=Welcome: Mercury Tours").Page("title:=Welcome: Mercury Tours").Image("file name:=banner2.*").Highlight
 
Browser("title:=Welcome: Mercury Tours").Page("title:=Welcome: Mercury Tours").Image("file name:=banner.*").Highlight
 
Browser("title:=Welcome: Mercury Tours").Page("title:=Welcome: Mercury Tours").Image("file name:=ban.*gif").Highlight
 
Browser("title:=Welcome: Mercury Tours").Page("title:=Welcome: Mercury Tours").Image("file name:=ban.*f").Highlight

Ofcourse, there are more ways to identify the banner image, but I’ve only used the above 5. Similarly, we can use this wildcard character for the Browser and Page objects:

' Without wildcard(s): 0.20 seconds
Browser("title:=Welcome: Mercury Tours").Page("title:=Welcome: Mercury Tours").Image("file name:=banner2.gif").Click
 
' With wildcard(s): 0.30 seconds
Browser("title:=Welcome.*").Page("title:=.*Mercury Tours").Image("file name:=banner2.gif").Highlight   
 
' 0.28 seconds
Browser("title:=Welcome:.*").Page("title:=Welcome.*").Image("file name:=banner2.*").Highlight          
 
' 0.56 seconds
Browser("title:=.*Mercury Tours").Page("title:=.*: Mercury.*").Image("file name:=banner.*").Highlight  
 
' 0.61 seconds
Browser("title:=.*Mercury Tour.*").Page("title:=Welcome:.*").Image("file name:=ban.*gif").Highlight    
 
' 0.51 seconds
Browser("title:=.*: Mercury.*").Page("title:=.*Mercury Tour.*").Image("file name:=ban.*f").Highlight

You might notice a little drop in performance for some of the above statements. This is quite obvious though. Using a real world example:

Scenario 1
If you were asked to deliver a letter to John and you had the following piece of information provided: Building 184, Floor 5, Room 120, Desk 9. You would know that you first have to find Building A, then take an elevator to the 5th floor, find Room 120, and once you’re inside room 120, John sits on Desk # 9. This is quite straight-forward and ofcourse you’ll be able to quickly find John.

Scenario 2
In another scenario, if you were asked to deliver a letter to John who is in Building 184 and on the 5th floor, how would you find John? You would have to go to each room and ask for John, and make sure it is the correct John before delivering the letter to him. This might take longer.

This is roughly what happens in our scripts. As our descriptions get more and more generic, the time it takes to identify the object increases. Therefore, even though wildcard characters can simplify our work, we should be a little careful how we use them.

Regular-Expressions.Info is a good source to learn regular-expressions. We will now do the exact same test we did about with Banner2.gif, but this time using some more regex style characters.

' Using the first few characters of the title and the first few characters of the image
Browser("title:=Welc\w+\D+\w+").Page("title:=Welc\w+\D+\w+").Image("file name:=ban\w+\d+\.\w+").Highlight
 
' Using the last few characters of the title with first and last characters of the image
Browser("title:=\w+\D+\w+ours").Page("title:=\w+\D+\w+ours").Image("file name:=b\w+2\.gif").Highlight
 
' Same as above for Browser and Page, but '...' for image
Browser("title:=\w+\D+\w+ours").Page("title:=\w+\D+\w+ours").Image("file name:=b\w+2\....").Highlight
 
' Same as above, but replaced 'b' with a '.'
Browser("title:=\w+\D+\w+ours").Page("title:=\w+\D+\w+ours").Image("file name:=.\w+2\....").Highlight

In the proceeding article we will cover Ordinal Identifiers and also see how to create a simple test module for a login process.

Descriptive Programming Series

1. Descriptive Programming (DP) Concepts – 1
2. Descriptive Programming (DP) Concepts – 2 {Regular Expressions}
3. Descriptive Programming (DP) Concepts – 3 {Ordinal Identifiers}
4. Descriptive Programming (DP) – 4 {Creating a Test Script)

References

1. Wildcard Character, Wikipedia
2. QuickTest Professional Help

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.

Introduction
Descriptive programming has become the technique of choice for many QTP test developers. We can talk about its advantages and disadvantages all day, but here, we’ll only discuss the concepts and come up with our own idea of what it does better, and what it doesn’t :). This is going to be a very quick refresher before we move on to its everyday application by completing an end-to-end testcase.

The idea behind descriptive programming is for automation developers to instruct QTP which properties they would like to use to identify an object, instead of having QTP to choose them itself. If done correctly, this can help create robustness in scripts, ultimately requiring less maintenance-time and more development time.

Let’s begin.

But wait, before we really begin, we must understand QTP’s Object Spy. It is an inbuilt tool that enlists all of the test-object and runtime-object properties. These properties are different for different types for objects. For example, an image has a property called ‘file name’ whereas a listbox doesn’t. Instead, a listbox has a special ‘all items’ property whereas the image doesn’t. This discussion will be limited to the usage test-object properties to identify objects. Below are 2 snapshots of the Object Spy:

Object Spy Icon

Object Spy Window

Now, let’s open www.Google.com and use the object spy to retrieve all properties of the search box:

Object Spy: WebEdit Properties

Notice the image above. The editbox has a HTML TAG property with its corresponding value ‘INPUT’. This means, the editbox takes some input from the user – which is true because we do set some value in it! It also has a ‘MAX LENGTH’ property, with a value of ’2048′. This means, you can enter a maximum of 2048 characters in it (the best source to see all of the Test-Object properties of objects is the QTP help itself). Below you will see an editBox which can contain a maximum of 9 characters:

Test maxLength:

You can really use all these properties to identify this editbox, but, do we really need to use all of them? No. That is the most important idea behind descriptive programming – we only use what we need. Below is how we write descriptions for objects:

ObjectClassName("property:=value", "property:=value")
 
' ofcourse we're not limited to only 2 properties. We can write more:
ObjectClassName("property:=value", "property:=value", "property:=value")

Above, ObjectClassName (in Web applications) can be Browser, Page, Frame, WebEdit, Image etc. Properties come from the left column the ObjectSpy column whereas values are in the right column. We can include as many properties as we want, but in reality, we only need to add a few to uniquely identify the object. Knowing which properties should suffice to uniquely identify can object will come from experience and practice. Below is a description I created for this editbox (WebEdit):

'ObjectClassName( "property1:=value1", "property2:=value2" )
WebEdit( "name:=q", "html tag:=INPUT" )

I already mentioned the HTML TAG and its value INPUT above. We’ve also added a new property/value here: ‘name:=q’. Is this enough to uniquely identify the object? Yes. But is it enough to make our script work? No, sadly its not.. and that is because, we haven’t yet created descriptions for its parent objects: Browser & Page. Below are the snapshots of the spied browser and page objects:

Object Spy: Browser Properties

Object Spy: Page Properties

Browser description:

'ObjectClassName( "property1:=value1" )
Browser( "title:=Google" )

Page description:

Page( "title:=Google" )

Now, we will connect all these descriptions and form a hierarchical tree:

Browser("title:=Google").Page("title:=Google").WebEdit("name:=q","html tag:=INPUT")

You might wonder why I have omitted the WebTable below the Page and above the WebEdit object. In practice, we can also skip the Page object to identify the WebEdit. But, why did I skip the WebTable after all!? When you experiment more with DP, you will discover that some objects are embedded in many WebTables, and it will become cumbersome if we were to include all WebTables in the hierarchy to get to the object of interest (thanks to the person who thought that will be a terrible idea!). Example of the previously mentioned scenario:

Object Spy: Multiple WebTables

To complete the statement above, we will add an event. In QTP, events can be described as actions on target objects. For example, a WebEdit has a ‘Set’ event. we use the ‘Set’ method of a WebEdit to set a value:

Browser("title:=Google").Page("title:=Google").WebEdit("name:=q","html tag:=INPUT").Set "DP"

Set is a QTP event to put in a value in the edit box. Different objects have different events. For example: an Image has a ‘Click’ event associated with it.

This, we did without using Object Repository. The same concept applies to all objects regardless of what your environment is. We perform actions on child objects by accessing their object hierarchies. Let’s complete the above example by searching for our keywords (use the spy again on the search button):

Browser("title:=Google").Page("title:=Google").WebEdit("name:=q", "html tag:=INPUT").Set "DP"
Browser("title:=Google").Page("title:=Google").WebButton("name:=Google Search").Click

This is how the same code will look like if we had recorded this process:

Browser("Google").Page("Google").WebEdit("q").Set "DP is great"
Browser("Google").Page("Google").WebButton("Google Search").Click

These properties are now stored in QTP’s Object Repository (OR). There is another way we can create object descriptions, which is done by setting a reference:

' Creating Browser description
' "title:=Google"
Set oGoogBrowser = Description.Create
oGoogBrowser( "title" ).value = "Google"
 
' Creating Page description
' "title:=Google"
Set oGoogPage = Description.Create
oGoogPage( "title" ).Value = "Google"
 
'* Creating WebEdit description
' "html tag:=INPUt", "name:=q"
Set oGoogWebEdit = Description.Create
oGoogWebEdit( "html tag" ).Value = "INPUT"
oGoogWebEdit( "name" ).Value = "q"

Once we do the above, we can use this descriptions in our script:

Browser(oGoogBrowser).Page(oGoogPage).WebEdit(oGoogWebEdit).Set "DP is great"

The only time I use this technique is to retrive object collections through ChildObjects (we will discuss this in the coming tutorials).

Let’s do another example. Again, we will use Google, but instead of setting a value, we will click an object. You can choose any Link on the page; I chose the link ‘Images’:

Object Spy: Google Images Link

'ClassName("property:=value").ClassName("propert1:=value").ClassName("property:=value").Event
Browser("title:=Google").Page("title:=Google").Link("innertext:=Images", "html tag:=A").Click

This time, instead of ‘Set’ we used ‘Click’. Following is a list of events we perform on Web objects:

Descriptive Programming Series

1. Descriptive Programming (DP) Concepts – 1
2. Descriptive Programming (DP) Concepts – 2 {Regular Expressions}
3. Descriptive Programming (DP) Concepts – 3 {Ordinal Identifiers}
4. Descriptive Programming (DP) – 4 {Creating a Test Script)

References

1. QuickTest Professional Help

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.