W3C defines a Web service as “a standard means of interoperating between different software applications, running on a variety of platforms and/or frameworks”. In simple terms, a Web service can be used to integrate web applications. In this exchange of data, XML is used to tag data, SOAP is used to transfer data, WSDL is used to describe how data is exchanged and finally, UDDI lists the services available. For further reading, you can visit XML Web Services Basics.

In this topic, we will be using 3 important objects and provide their overview before diving deep into this topic. They are:

1. XMLUtil
2. XMLDOM
3. XMLHTTPRequest

XMLUtil

XMLUtil object provided with QTP is used to access and return XML objects. In other words, XMLUtil can be used to access or expose the contents of an XML file. XMLUtil supports the following 2 methods to create and return an object of type XMLData:

1. CreateXML Method
2. CreateXMLFromFile

More information regarding XMLUtil can be located at QuickTest Professional Object Model Reference.

XMLDOM

Similar to XMLUtil object used in QTP, XMLDOM also provides methods and properties to access and return XML objects. I am more accustomed to using this object as opposed to XMLUtil, but they can be both used interchangeably. For further reading, you can visit A Beginner’s Guide to the XML DOM. To create an instance of XMLDOM, CreateObject must be used.

Set xmlParser = CreateObject("Microsoft.XMLDOM")

XMLHTTPRequest

Unlike XMLUtil and XMLDOM, which are both XML parsers, the XMLHTTPRequest object is an API used to send HTTP or HTTPS requests directly to a Web Server and receiving the response using its Post, Send and Get methods. For further reading, you can visit XMLHttpRequest object. To create an instance of XMLHTTPRequest, CreateObject must be used.

Set XMLHTTPRequest = CreateObject("Microsoft.XMLHTTP")

Google Maps – The Distance Matrix API

The Google Distance Matrix API is a Web service used to provide travel distance and time for travel start (origins) and end points (destinations). The response from the API consists of rows containing data for each origin and destination pair.

To request information from the Distance Matrix API, the following URL with output type and input parameters must be used:

http://maps.googleapis.com/maps/api/distancematrix/output?parameters

Output

Output may be in either JSON or XML. In this topic, XML will be used.

Parameters

There is a total of 7 parameters that can be used to request information back from the API. 4 of these parameters are optional.

1. Origins (required)
2. Destinations (required)
3. Mode (optional)
4. Language (optional)
5. Avoid (optional)
6. Units (optional)
7. Sensor (required)

For more information, you can refer to the Distance Matrix API documentation.

I feel we’ve covered enough basics and its time to dig into exchanging data with the Distance Matrix API and then, parse it to get values we’re concerned with. Below are the values we will be using to request data:

• output = xml
• origins = Atlanta, GA, USA
• destinations = Dallas, TX, USA
• units = imperial (in miles)
• sensor = False

The final URL string:

http://maps.googleapis.com/maps/api/distancematrix/xml?origins=Atlanta+GA+USA&destinations=Dallas+TX+USA&units=imperial&sensor=false

I also computed the distance using the Google Maps UI (maps.google.com) and got the following result. The result below should match the result obtained from XMLHTTPRequest.

Requesting Information from Distance Matrix API

In the following code, XMLHTTPRequest object is used to send the string above and receive the corresponding response from the Distance Matrix API.

url = "http://maps.googleapis.com/maps/api/distancematrix/xml?" & _
		"origins=Atlanta+GA+USA&" & _
		"destinations=Dallas+TX+USA&" & _
		"units=imperial&" & _
		"sensor=false"
 
Set oReq = CreateObject("Microsoft.XMLHTTP")
 
oReq.open "POST", url, False
oReq.send
 
'Response
responseText = oReq.responseText
 
Print responseText

Output

<?xml version="1.0" encoding="UTF-8"?>
<DistanceMatrixResponse>
 <status>OK</status>
 <origin_address>Atlanta, GA, USA</origin_address>
 <destination_address>Dallas, TX, USA</destination_address>
 <row>
  <element>
   <status>OK</status>
   <duration>
    <value>47410</value>
    <text>13 hours 10 mins</text>
   </duration>
   <distance>
    <value>1254681</value>
    <text>780 mi</text>
   </distance>
  </element>
 </row>
</DistanceMatrixResponse>

Simple, isn’t it? Receiving the response is one thing, parsing it for data important to us is another. In the next part, parsing the above XML will be shown using both XMLUtil and XMLDOM objects.

Parsing Information using XMLUtil, XMLDOM

In the last section, we received some data from Google’s Distance Matrix API by using the .responseText method of XMLHTTPRequest. In this section, we will parse the ResponseText to retrieve the time taken and distance of travel. Below are the 2 nodes from the output above we’re concerned with:

DistanceMatrixResponse\row\element\duration\text
DistanceMatrixResponse\row\element\distance\text

I have used the method GetValueByXPath but you can also use ChildElements and ChildElementsByPath methods.

XMLUtil

sNodeDistance = "row/element/distance/text"
sNodeDuration = "row/element/duration/text"
 
Set oParser = XMLUtil.CreateXML()
 
'Note: responseText comes from XMLHTTPRequest in the previous section
oParser.Load responseText
 
'Using the XPath above to retrieve distance
nodeDistance = oParser.GetRootElement.GetValueByXPath(sNodeDistance)
 
'Using the XPath above to retrieve duration
nodeDuration = oParser.GetRootElement.GetValueByXPath(sNodeDuration)
 
Print nodeDistance
Print nodeDuration

Output

With XMLDOM, I have used the method selectSingleNode but you could also use selectNodes, getElementsByTagName etc. to drill down to the target node.

XMLDOM

sNodeDistance = "row/element/distance/text"
sNodeDuration = "row/element/duration/text"
 
Set oParser = CreateObject("Microsoft.XMLDOM")
 
'Note: responseText comes from XMLHTTPRequest in the previous section
oParser.loadXML(responseText)
 
'Distance node: comes from XPath above
Set nodeDistance = oParser.documentElement.selectSingleNode(sNodeDistance)
 
'Duration node: comes from XPath above
Set nodeDuration = oParser.documentElement.selectSingleNode(sNodeDuration)
 
Print nodeDistance.text
Print nodeDuration.text

Output

Summary

In this topic, we saw how to send a request and receive response using XMLHTTPRequest. Later, to parse the response, we used XMLDOM and XMLUtil to retrieve the results.

I have been using classes in my frameworks for a long time now, and my biggest gripe about QTP is its lack of Intellisense for custom classes. It also happens to be my biggest complaint. I understand this is not high priority for HP to include in its newer versions as there is a very small group of people who use OO techniques in test automation with QTP. There has been another workaround by Yaron, who used WSC to create intellisense.

I have been researching this topic and I finally have a workaround which I have tested for for the past few weeks with great success. The best part about this workaround is, I just need to create wrappers, without including any of the code I have in my QTP function libraries. If I add a new method to my class, all I do to update the Intellisense is add the method (without the QTP code) in my VB lib, create a DLL and Register the library for COM Interop.

Let’s get working then!

Step 1: Create your QTP Modular/Custom/Generic Class

Class LoginClass
 
'#region Private Variables
    Private UserName    'As String
    Private UserRole    'As String

'#region Public Variables
    Public PageTitle    'As String
    Public LinksCount   'As Integer
    
'#region Public Methods
    Public Sub CheckLinks()
        Dim arrLinks
 
        arrLinks = Array("Home", "Register", "Language", "Sign-In")
 
        Call FunctionToCheckLinks(arrLinks)
    End Sub
 
    Public Function IsPageFound() 'As Boolean
        If Browser("title:=MyApp").Exist(15) Then IsPageFound = True
    End Function
 
'#region Class Constructor & Destructor
    Private Sub Class_Initialize()
        UserName = "test"
        UserRole = Global.UserRole
    End Sub
 
    Private Sub Class_Terminate
        'code
    End Sub
 
End Class
 
Public LoginX: Set LoginX = New LoginClass

Step 2: Converting QTP Class into VB.NET code

The next step is converting the method and property names to VB.NET. If you have never used VB.NET, don’t be scared! The syntax is quite straight-forward. The only thing to note here is, you must return values for Functions and Property Get. Also, the syntax of the Property construct differs slightly in VB.NET. Still, all you are including here are the names. You do NOT have to add the code from your QTP methods.

Always remember to include the Microsoft.VisualBasic.ComClass() flag before the class, and also, remember to make the class Public

All that goes in the VB.NET code are the names of the properties and methods. Do not include any QTP code here!

Below is a conversion of the QTP code above, to VB.NET. Notice that I have not included any of the code from my QTP class here:

Save the converted code in a .VB format file

Namespace RelevantCodes
    <Microsoft.VisualBasic.ComClass()> Public Class LoginClass
 
        Public Property PageTitle As String
            Get
                return "title"
            End Get
            Set(ByVal value As String)
                'code
            End Set
        End Property
 
        Public Property LinksCount As Integer
            Get
                return 10
            End Get
            Set(ByVal value As Integer)
            End Set
        End Property
 
        Public Sub CheckLinks()
        End Sub
 
        Public Function IsPageFound() As Boolean
        End Function
 
    End Class
End Namespace

Also remember that, your Public variables become Public Properties in VB.NET.

Step 3: Creating DLL from VB.NET Class using VBC.exe

Once our class is ready and we have saved it in .vb format, let’s create the DLL using VB’s command line compiler VBC/target:library creates a .NET code library (DLL), which is what we’re looking for.

C:\windows\Microsoft.NET\Framework\v2.0.50727\vbc.exe /target:library c:\RelevantCodes.vb

Executing the above syntax in cmd.exe will create a DLL file: RelevantCodes.DLL.

The path to your VBC.exe file may be different than the one I have used.

Step 4: Registering Class using RegAsm.exe

Next, we will use the .NET assembly registration tool RegAsm.exe that reads the metadata within an assembly (which we created using VBC.exe) and adds the necessary values to your registry. RegAsm.exe syntax: regasm assemblyFile [options].

C:\windows\Microsoft.NET\Framework\v2.0.50727\regasm.exe c:\Relevantcodes.dll /codebase

If QTP is already open, save all your tests and resources with libraries and re-open it. Launch it, and use CreateObject to create an instance of your class to see if its working. The syntax will be:

Set InstanceName = CreateObject("Namespace.Class")
 
'for our class:
Set LoginX = CreateObject("RelevantCodes.LoginClass")

You must see Intellisense for the instance to ensure everything has been a success until now. If this works, rest is just adding a few values to Registry and we’re done!

Step 5: Adding the Class Reference as a QTP Reserved Word

If the above works, we’re almost done! To get the intellisense for your class, we need to navigate to the registry key below and add a few values to the new key you create. Navigate to the following key in regedit.exe:

HKEY_CURRENT_USER\Software\Mercury Interactive\QuickTest Professional\MicTest\ReservedObjects\

If the above tree does not exist, try this:

HKEY_LOCAL_MACHINE\Software\Mercury Interactive\QuickTest Professional\MicTest\ReservedObjects\

Once you’re there, add a new key under reserved objects. You can give this key any name. What I generally do is, I give the same name as my QTP class. My key, then, becomes LoginClass. Once the key is created, I create the following entries in the key: ProgID (string), UIName (string) and VisibleMode (DWord).

New Key in \ReservedObjects: Name of your QTP Class

String: ProgID,      Value: Namespace.ClassName
String: UIName,      Value: Name of your reference for your custom QTP class
DWord:  VisibleMode, Value: 2

Therefore, in our case, considering the above, we will have the following values:

New Key in \ReservedObjects: LoginClass

String: ProgID,      Value: RelevantCodes.LoginClass
String: UIName,      Value: LoginX
DWord:  VisibleMode, Value: 2

The final output of adding the key and all entries to it must look like below:

Step 6: Reference the Class Instance with another Keyword

Lastly, all you need to do now is add a new variable and reference your Class Instance with it (as shown by Login below):

Public LoginX: Set LoginX = New LoginClass
Public Login : Set Login = LoginX

To create your tests and to get Intellisense, remember to associate your library with the test and use the Login keyword to see the intellisense.

I need to add a new method to my existing class. How do I do that!?!!

Well, once you converted the code for your original VB.NET library, DO NOT delete it. Once you add a new Public method to your QTP class, just add it to your VB.NET code, create (update) DLL using VBC.exe and re-register it using RegAsm. The new methods will now be available.

Summary

In summary, you have to follow the below 6 steps to create Intellisense for your custom QTP class:

1. Create your QTP class
2. Convert “Public” QTP methods to VB.NET (only the method names required!)
• Public Class
• Microsoft.VisualBasic.ComClass() attribute
3. Use VBC.exe to create .NET library
• Creates a DLL in the same location as the .VB file
4. Use RegAsm.exe Assembly Registration tool to add necessary values to Registry
5. Add the Class Instance as a Reserved word in Registry
6. Reference the class with another Keyword

I hope you will find this helpful. As always, thanks for visiting Relevant Codes :)

A lot of time and effort has been put into this article, to research and to test it. The information here is available absolutely free of cost. If you like this article, and if it works for you, please make a donation to a charity of your choice. There is no way we will be able to check if you did, but we know you will. There is a lot of on-going crisis today, and your donation will only help. Thank you.

This article shows a simple way of finding out in which cell a QTP’s Test Object resides. I find the method shown in this article a more effective and faster way of finding the cell I’m looking for. I have found that this method performs better than traversing rows/cells of a WebTable using in-built WebTable methods such as ChildItem, ChildItemCount and GetCellData. Also, for test objects, it is also not possible to find an exact match with the methods provided for WebTable – it is only possible for strings.

A workaround to find objects inside WebTable using DOM table/tr/td is shown in this article. The code snippets below show how to retrieve the row and column of a given object from a WebTable.

Consider the element “Doe” in the table below. We can visually see that the link is in the 5th row (starting at the heading) and the 3rd column.

Executing the following code will provide us our expected output:

Set element = Browser("creationtime:=0").WebElement("innertext:=Doe", "index:=0")

MsgBox "Row# " & element.GetRow()
MsgBox "Col# " & element.GetColumn()

The above example uses WebElement, but this approach works for all Web objects. Similarly, the code for finding the 2nd WebCheckBox for Anne Johnson will give us: Row# 3 and Column#5 with the following code:

MsgBox Browser("creationtime:=0").WebCheckBox("name:=attending", "index:=1").GetRow
MsgBox Browser("creationtime:=0").WebCheckBox("name:=attending", "index:=1").GetColumn

The Code

The following two methods can be used directly for the object and will retrieve ‘either’ the row or the column. The below method retrieves the Row for an object residing in a WebTable:

Find Row of the Object from WebTable

Function GetRow(ByVal TObject)
    GetRow = -1
 
    Set TObject = TObject.Object
 
    Do
        If TObject.nodeName = "TR" Then
            GetRow = TObject.rowIndex + 1
            Exit Function
        End If
 
        Set TObject = TObject.parentNode
    Loop Until TObject.nodeName = "HTML"
End Function
 
RegisterUserFunc "Image", "GetRow", "GetRow"
RegisterUserFunc "Link", "GetRow", "GetRow"
RegisterUserFunc "WebEdit", "GetRow", "GetRow"
RegisterUserFunc "WebList", "GetRow", "GetRow"
RegisterUserFunc "WebCheckBox", "GetRow", "GetRow"
RegisterUserFunc "WebElement", "GetRow", "GetRow"
RegisterUserFunc "WebRadioGroup", "GetRow", "GetRow"

Example

MsgBox Browser("title:=myBrowser").Link("innertext:=myLink", "index:=1").GetRow

This method returns the column of the object inside a WebTable:

Find Column of the Object from WebTable

Function GetColumn(ByVal TObject)
    GetColumn = -1
 
    Set TObject = TObject.Object
 
    Do
        If TObject.nodeName = "TD" Then
            GetColumn = TObject.cellIndex + 1
            Exit Function
        End If
 
        Set TObject = TObject.parentNode
    Loop Until TObject.nodeName = "HTML"
End Function
 
RegisterUserFunc "Image", "GetColumn", "GetColumn"
RegisterUserFunc "Link", "GetColumn", "GetColumn"
RegisterUserFunc "WebEdit", "GetColumn", "GetColumn"
RegisterUserFunc "WebList", "GetColumn", "GetColumn"
RegisterUserFunc "WebCheckBox", "GetColumn", "GetColumn"
RegisterUserFunc "WebElement", "GetColumn", "GetColumn"
RegisterUserFunc "WebRadioGroup", "GetColumn", "GetColumn"

Example

MsgBox Browser("title:=myBrowser").Link("innertext:=myLink", "index:=1").GetColumn

The below implementation retrieves both row and column as a Scripting.Dictionary.

Find Row & Column Info as Scripting.Dictionary

Function CellInfo(ByVal TObject)
    Dim dic
 
    Set dic = CreateObject("Scripting.Dictionary")
    dic.Add "row", -1
    dic.Add "col", -1
 
    Set TObject = TObject.Object
 
    Do
        If TObject.nodeName = "TD" Then dic("col") = TObject.cellIndex + 1
 
        If TObject.nodeName = "TR" Then
            dic("row") = TObject.rowIndex + 1
            Exit Do
        End If
 
        Set TObject = TObject.parentNode
    Loop Until TObject.nodeName = "HTML"
 
    Set CellInfo = dic
End Function
 
RegisterUserFunc "Image", "CellInfo", "CellInfo"
RegisterUserFunc "Link", "CellInfo", "CellInfo"
RegisterUserFunc "WebEdit", "CellInfo", "CellInfo"
RegisterUserFunc "WebList", "CellInfo", "CellInfo"
RegisterUserFunc "WebRadioGroup", "CellInfo", "CellInfo"
RegisterUserFunc "WebElement", "CellInfo", "CellInfo"
RegisterUserFunc "WebCheckBox", "CellInfo", "CellInfo"

Example

Set cells = Browser("title:=myBrowser").Link("innertext:=myLink", "index:=1").CellInfo()

MsgBox cells("row")
MsgBox cells("col")

cells.RemoveAll
Set cells = Nothing

I hope you find this helpful. As always, thanks for visiting Relevant Codes :)

Over the past few years, I have read numerous threads and posts talking about working with Excel using VBScript. Not only have there been numerous threads, but also frameworks that use Excel as the input and/or driver engine. I wanted to work on this mini-project for a long time, and I finally have Version 1.0 of ExcelUtil ready for download! It comes with .CHM documentation.

I’m quite sure I have missed some methods that the community uses, which I have not been able to include in the 1st version. I, however, am open to suggestions and would gladly include your ideas for Version 2.0.

Download RelevantCodes.ExcelUtil Class Library (1302)

IMPORTANT: To use any method of ExcelUtil, be sure to use SetFile. This will set the Excel WorkBook and WorkSheet ready for use. To use a different WorkBook or WorkSheet, SetFile will have to be called again.

SetFile Property

Value Type

Read only. A [RelevantCodes.ExcelUtil] object.

Description

Sets the region instances for Excel WorkBook and WorkSheet. These instances for the Excel source are created only once and used by other methods. NOTE: For any method to execute, SetFile must be executed first to set the WorkBook and WorkSheet.

Syntax

ExcelUtil.SetFile WorkBookPath, WorkSheet

Examples

'Example 1
ExcelUtil.SetFile "C:\Student.xls", "Sheet1"
 
'Example 2:  Reading value directly from a file
sCellValue = ExcelUtil.SetFile("C:\Student.xls", "Sheet1").GetCellValue(1, 1)
 
'Example 3:  Reading values from 2 different files - Approach 1
ExcelUtil.SetFile "C:\Student.xls", "Sheet1"
var1 = ExcelUtil.GetCellValue(1, 1)
ExcelUtil.SetFile "C:\Teacher.xls", "Sheet1"
var2 = ExcelUtil.GetCellValue(1, 1)
 
'Example 4:  Reading values from 2 different files - Approach 2
var1 = ExcelUtil.SetFile("C:\Student.xls", "Sheet1").GetCellValue(1, 1)
var2 = ExcelUtil.SetFile("C:\Teacher.xls", "Sheet1").GetCellValue(1, 1)

I found a Bug. What should I do next?

Reporting the bug in the comments section will ensure the next version of this class library is more robust! It may not be possible to release the fixed code immediately, but notifying me and the readers of all potential bugs will be highly appreciated! Thank you.

I have something cool I would like you to add to ExcelUtil.

I would love to hear all ideas and suggestions to improve or enhance this library. Please use the comments section to share them with me and the community. Thank you.

Download RelevantCodes.ExcelUtil Class Library (1302)

For the past few weeks, I have been actively working on Quality Center (ALM) and its integration with QuickTest Professional. One of the mini-projects I’ve worked on is creating a custom object that executes a test set and sends an email to the supplied distribution list from ALM TestSet’s Automation tab (as shown below):

Note: The above part (EMailTo) can be modified by either hard-coding it, or supplying an input from the Class Constructor.

I’ve extensively used the OTA API Reference to build this object and to understand how the API works. .NET developers having difficulty converting the VBScript code, please post in the comments section and I will mail you the class library (currently only C#).

Download (ALM Only)

QCRunTestSet is available for download, but comes as-is and currently executes TestSets on the localHost. However, I would be more than happy in helping you to modify this code to suit your needs.

QCRunTestSet.cls.vbs.zip [for ALM] (1610)

If you’re having issues creating an instance of the TSScheduler object, please read this thread carefully. You may need to upgrade to a higher patch or perform a client registration on the execution machine.

Running QCRunTestSet from CommandLine

If you would like to pass parameters from the CommandLine instead of hard-coding them in the code, use WScript to pass arguments and WScript.Arguments to retrieve them in the class library. Example:

'Passing arguments
wscript C:\QCRunTestSet.cls.vbs "http//<server>:8080/qcbin" myUser myPassword myDomain _
                                                  myProject myTestSetPath myTestSetName

'Retrieving arguments
Set args = WScript.Arguments
 
QCServer = args(0)
UserName =  args(1)
Password = args(2)
QCDomain = args(3)
QCProject = args(4)
QCTestSetPath = args(5)
QCTestSetName = args(6)

I hope you find this helpful. Thanks for visiting Relevant Codes! :)

While testing a script on IE8, me and my colleague kept getting the error “A script on this page is causing Internet Explorer to run slowly”. Below is a snapshot of the error:

After some research, I came across an article on MSDN which already had the solution: Microsoft KB # 175500. The part we are concerned about is in the section “Let me fix it myself”:

1.Using a Registry Editor such as Regedt32.exe, open this key: HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Styles
Note: If the Styles key is not present, create a new key that is called Styles.
2. Create a new DWORD value called “MaxScriptStatements” under this key and set the value to the desired number of script statements. If you are unsure of what value you need to set this to, you can set it to a DWORD value of 0xFFFFFFFF to completely avoid the dialog.

For the curious ones, the article states that, to encounter the error, the DWord value of 0xFFFFFFFF must be added. The value equates to -1, which is what has been used in the function below.

Code

Sub IE_ChangeScriptTimeOut()
	Dim Registry, sKeyPath, sValueName, dwValue, sComputer
	CONST HKEY_CURRENT_USER = &H80000001
 
	sKeyPath = "Software\Microsoft\Internet Explorer\Styles"
	sValueName = "MaxScriptStatements"
	dwValue = -1
	sComputer = "."
 
	On Error Resume Next
		Set Registry = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" &_ 
				sComputer & "\root\default:StdRegProv")
 
		Registry.CreateKey HKEY_CURRENT_USER, sKeyPath
		Registry.SetDWORDValue HKEY_CURRENT_USER, sKeyPath, sValueName, CLng(dwValue)
	On Error Goto 0
 
	Set Registry = Nothing
End Sub

Thanks for reading, and thanks for visiting Relevant Codes! :)

I’ve generally seen some confusion around CreationTime. I think between the 3 Ordinal Identifiers, this one may be the easiest to understand and implement. That’s mostly because CreationTime is used only for the Browser object. Below is how CreationTime is applied to browsers:

1st open browser -> CreationTime of -> 0
2nd open browser -> CreationTime of -> 1
3rd open browser -> CreationTime of -> 2
4th open browser -> CreationTime of -> 3

According to QTP help:

This value indicates the order in which the browser was opened relative to other open browsers. For example, if QuickTest learns three browsers that are opened at 9:01 pm, 9:03 pm, and 9:05 pm, QuickTest assigns the CreationTime values, as follows: CreationTime = 0 to the 9:01 am browser, CreationTime = 1 to the 9:03 am browser, and CreationTime = 2 to the 9:06 am browser.

Really, that’s it! No tricks here! To test it for proof, you can open 4 browsers (with different websites) and run the following code in QTP:

For ix = 0 to 3
	Print "CreationTime->" & ix & "->" & Browser("creationtime:=" & ix).GetROProperty("title")
Next

On my desktop, I’ve 4 open IE windows in the following order: Google, Bing, Yahoo, Microsoft. See snapshot below:

My taskbar: Click to view original size

After running the above code, this is what I see in my print log:

Print log

The output shows the order in which the IE windows are placed on the Desktop, which is same as the order in which they were opened.

The tricky part

The only tricky part in this concept is its applicability when there is only one browser open. With one open browser, regardless of the CreationTime value supplied, QTP will always identify the only open browser. This is because, CreationTime values are generated when there are multiple browsers open – with a single open browser, this value is generally has no usage. This is at least true for QTP 10.0 and previous versions.

As always, thanks for visiting Relevant Codes! :)

VBScript’s error handling techniques have been quite limited to On Error statements, and even though they satisfy our needs to some extent, the lack of incorporating dynamic behavior with them has been a much bigger issue. Lee Harvey here shows how Classes can be extended to create simple Try-Catch-Finally statements with just a bit more work. I like this technique, and have been using it for the past few days with success. We know that this is not the best solution that is possible with a scripting language (JS does a lot better!), but its a start and a terrific workaround (thanks Lee!).

Creating Try-Catch-Finally Statements in VBScript

If you have already read Lee’s article, you can skip this part. Otherwise, a simple implementation is shown below:

1. As soon as the class executes, it enters Class_Initialize – Try statement
2. It encounters an error – Err.Raise 1002
3. As soon as it encounters an error, the Try statement (Class_Initialize) immediately ends execution
4. Because we’re releasing the Class reference using Set NewTryCatchFinally = Nothing right after initializing it, the Class enters Class_Terminate
5. Class_Terminate calls the Catch subroutine
6. When Catch runs in its entirety, Class_Terminate executes

On Error Resume Next
 
Class TryCatchFinally
 
    Private Sub Class_Initialize 'Try
        Print "Entering Try.." & vbNewLine
 
        Err.Raise 1002 'Raise a Syntax Error
        MsgBox "This line will not execute"
    End Sub
 
    Private Sub Catch 'Catch
        If Err.Number = 0 Then Exit Sub
 
        Print "Entering Catch.."
        Print "Error caught: " & Err.Description  & vbNewLine
 
        Err.Clear
    End Sub
 
    Private Sub Class_Terminate : Catch 'Finally
        Print "Exiting.." 
    End Sub
 
End Class
 
'Enters Try (Error occurs)
Set NewTryCatchFinally = New TryCatchFinally 
 
'Enters Catch, then Finally
'Catch will only execute if Error occured
Set NewTryCatchFinally = Nothing

The output of executing the above code should be the following:

Try Catch Finally Implementation in VBScript

We can see from the result that as soon as the Class executes, it enters Class_Initialize. When it encounters an error, it enters into Class_Terminate which contains (and executes) the Catch method. A simple yet such an elegant solution!

Utility Class & Error Handler

In this article, I will try to implement the technique with QTP’s GUI objects. To begin, let’s create a simple Login class with the following methods:

1. CheckPage
2. CheckImage
3. Login

The Login Class outputs the result through the Result property:

A simple Login Class

On Error Resume Next
 
Class Login
 
    Public Property Get Result
        Result = CheckPage And CheckImage And Login
    End Property
 
    Private Function CheckPage
        MsgBox "CheckPage" : CheckPage = True
    End Function
 
    Private Function CheckImage
        CheckImage = False
 
        Browser("title:=Welcome.*").WebElement("text:=Relevant Codes").Click 'Error here!

        MsgBox "Error!" 'This will not execute
    End Function
 
    'This will not execute
    Private Function Login
        MsgBox "Login"
    End Function
 
End Class
 
Dim NewLogin : Set NewLogin = New Login

Above, the Result property of the Login Class is called, which first executes CheckPage, then CheckImage and finally Login. Note that Login will only execute if CheckImage runs without any errors.

Let’s create another class that calls the methods of the original Login class, but with the error handling capabilities of a Try-Catch-Finally statement. This is also the Class that will always execute the original Login class because that’s where the actual error handling using Try-Catch-Finally exists.

Try..Catch..Finally with Class_Initialize & Class_Terminate

Class LoginHandler 'LoginHandler start

    Public bResult
 
    Private Sub Class_Initialize
         Print "Entering Try.." & vbNewLine
         bResult = NewLogin.Result
    End Sub
 
    Private Sub CatchErr
        If Err.Number = 0 Then Exit Sub
 
        Print "Entering Catch.."
        Print "Error: " & Err.Description & vbNewLine
 
        Err.Clear
    End Sub
 
    Private Sub Class_Terminate : CatchErr
        Print "Exiting.."
    End Sub
 
End Class 'LoginHandler end

'NewLoginHnder executes the Login Class in 'try'
Set NewLoginHandler = New LoginHandler
 
'Releasing the instances invokes CatchErr, then Class_Terminate()
Set NewLoginHandler = Nothing
 
'Release NowLogin instance
Set NewLogin = Nothing

The Class_Initialize method of the class calls the Result property of the Login class. Once Result is called, it executes all the methods called by the Result property. If any error occurs, CatchErr is immediately called by Class_Terminate and later, all code inside the Class_Terminate method is executed.

Output of executing Login Class & LoginHandler:

QTP Print Log

Method Containing the Error?

By including the name of each method in the very first line, we can also find out where exactly the error occurred. This, however, I agree is quite time consuming and repetitive work. The only alternative to this has been shown by PowerDebug Beta. However, if you would like to extend the above approach in VBScript, this *may be* the only possible approach. I’ve been wrong before, and would love to see a technique which simplifies the method naming approach used below.

Login Class with Method Names

On Error Resume Next
 
Class Login 'Login start

    Public sMethod
 
    Public Property Get Result
        Result = CheckPage And CheckImage And Login
    End Property
 
    Private Function CheckPage
        Me.sMethod = "CheckPage"
 
        MsgBox "CheckPage" : CheckPage = True
    End Function
 
    Private Function CheckImage
        Me.sMethod = "CheckImage"
 
        CheckImage = False
        Browser("title:=Welcome.*").WebElement("text:=Relevant Codes").Click 'Error here!
        
        MsgBox "Error!" 'This will not execute
    End Function
 
    Private Function Login 'This will not execute
        Me.sMethod = "Login"
 
        Msgbox "Login"
    End Function
 
End Class 'Login end
Dim NewLogin : Set NewLogin = New Login

LoginHandler (Outputs Method Names)

Class LoginHandler 'LoginHandler start

    Public bResult
 
    Private Sub Class_Initialize
         Print "Entering Try.." & vbNewLine
         bResult = NewLogin.Result
    End Sub
 
    Private Sub CatchErr
        If Err.Number = 0 Then Exit Sub
 
        Print "Entering Catch.."
        Print "Error occured in: " & NewLogin.sMethod
        Print "Error: " & Err.Description & vbNewLine
 
        Err.Clear
    End Sub
 
    Private Sub Class_Terminate : CatchErr
        Print "Exiting.."
    End Sub
 
End Class 'LoginHandler end

Set NewLoginHandler = New LoginHandler
Set NewLoginHandler = Nothing
Set NewLogin = Nothing

View code.

Output of executing Login Class & LoginHandler:

QTP Print Log

Notes

After using this technique for several days and manipulating it a bit from the original work, I have found some success. However, implementing Handler classes when the scope of the utility class increases can be quite challenging, and time consuming. I still believe its a start to something that we haven’t witnessed in QTP (yet). To be honest, I still prefer the old way of doing things where I can branch out most of my GUI code in conditional statements – which has enabled me to always create more comprehensive reporting.

My recommendation would be to use this approach with VBScript code instead of using it for QTP’s GUI objects, ofcourse, until absolutely necessary. Most of my usage for the above technique has been with pure VBScript code which has enabled me to create better error handling. In an upcoming article, I will show how this technique will be used to handle Excel errors and recover from them in the CatchErr method using a Select Case block. Including Try-Catch-Finally statements within Try-Catch-Finally statements is quite easily done in .NET, but its very complex to perform the same operation with VBScript. I’m still happy to have a start though.

This has been tested to work correctly on QTP versions: 9.5+.

There is a common perception that we must include the Browser object in hierarchies when working in the Web environment. The truth is that, we really don’t need to include the Browser object if the Page object has been included in the hierarchy.

In other words, the commonly written inline statements for Web environment:

Browser("title:=Google").Page("title:=Google").WebEdit("name:=q").Set "Test"
Browser("title:=Google").WebEdit("name:=q").Set "Test"

can also be written like this:

Page("title:=Google").WebEdit("name:=q").Set "Test"

Quick tip! Thanks for visiting Relevant Codes! :)

This topic covers the concepts of the Eval function and Execute statement in depth. The function Eval is used to evaluate a string and return the result of the string expression. The Execute statement on the other hand, executes one or more statements in a string expression and enables creation of dynamic code. Multiple statements can be executed at once by using colons or line breaks to separate them.

If you have had a chance to use RelevantCodes[1]One and went over the function libraries, you would find that all the events are controlled through Execute statement – data is retrieved from the Excel Table and parsed by the function libraries into string statements. Once parsed, these string statements are then executed in the same manner as QTP code.

Eval Syntax

Eval(expression)

Execute Syntax

Execute statement

Difference between Eval & Execute

In the syntax above, both expression and statement arguments are string statements. Both expressions can be derived from VBScript or QTP code; the difference lies in the fact that Eval will always return the result of the string evaluation whereas Execute will execute a string statement for execution and will not retrieve the result (but there are workarounds). The following example demonstrates the main difference between the 2 functions:

x = 9
y = 10
 
bIsEqual = Eval("x = y")
Execute "x = y"
 
MsgBox "bIsEqual: " & bIsEqual
MsgBox "X is no longer 9. It is: " & x

Eval Function

Execute Statement

Note that Eval returned a Boolean value whereas Execute function performed a variable assignment. This article will cover the usage of both techniques in depth through both VBS and QTP code.

You must be wondering why the syntax for Eval and Execute is different. The reason is that, Eval is a function. Execute is not. That means, the following statement for Eval: bIsEqual = Eval("x = y"), when written for Execute will return a Null value for bResult (but assignment will be performed for x):

bResult = Execute("x = y")
MsgBox bResult
MsgBox "x: " & x

Null Output

X = 10

With that said, let me share the workaround that can be used with Execute to return the evaluation just like we did with Eval. Here’s how:

x = 9
y = 10
 
Execute "z = (x = y)"
MsgBox "z: " & z

Return Z (False)

More on this concept will be covered in the section Evaluating Statements.

Creating Variables

Let’s assume a scenario where you need to create the following variables: var_1, … , var_5. One way is to manually create the variables:

var_1 = 1 : var_2 = 2 : var_3 = 3 : var_4 = 4: var_5 = 5

A quicker, and more dynamic way to achieve the same is through Execute statement:

For ix = 1 to 5
    Execute "var_" & ix & " = " & ix
Next

Option Explicit

Using the Execute statement also has a direct impact if the Option Explicit statement is ON. If a variable is not explicitly declared, an error will be occurred:

Option Explicit
 
iNumber = 9

When the same variable is created through Execute, the error will not occur and the variable will be created and value assigned successfully.

Option Explicit
 
Execute "iNumber = 9"

Evaluating Statements

Instead of equating variables and values, we will evaluate statements using Eval. A quick example using IsObject is demonstrated below:

Set dicObject = CreateObject("Scripting.Dictionary")
 
If Eval("IsObject(dicObject)") Then
    MsgBox "Object created."
    Set dicObject = Nothing
End If

Similarly, the above code can be broken into a Select Case block and variables can be evaluated by their type:

Sub RetType(ByVal var)
	Select Case Eval("TypeName(var)")
		Case "Integer" : MsgBox "Integer"
		Case "Dictionary" : MsgBox "Dictionary"
		Case "Nothing" : MsgBox "Nothing"
		Case "String" : MsgBox "String"
	End Select
End Sub
 
Call RetType(Nothing)
Call RetType("Test")
Call RetType(CreateObject("Scripting.Dictionary"))
Call RetType(1)

Upon execution, the following results will be retrieved:

RetType(Nothing)

RetType('Test')

RetType(CreateObject)

RetType(1)

The same function above can be written through Execute. However, with Execute, we cannot directly retrieve the result (it is not a function, unlike Eval). Therefore, we will create a variable and store the result with the variable; the variable will then be used as the Select Case condition.

Sub RetType(ByVal var)
	Dim bResult
 
	Execute "bResult = TypeName(var)"
 
	Select Case bResult
		Case "Integer" : MsgBox "Integer"
		Case "Dictionary" : MsgBox "Dictionary"
		Case "Nothing" : MsgBox "Nothing"
		Case "String" : MsgBox "String"
	End Select
End Sub
 
Call RetType(Nothing)
Call RetType("Test")
Call RetType(CreateObject("Scripting.Dictionary"))
Call RetType(1)

In short then, with Execute, bResult is represented within the string statement:

Execute "bResult = TypeName(var)"

With Eval, bResult is an actual variable that holds the result like below:

bResult = Eval("TypeName(var)")

Creating Functions

I have seen this approach rarely used, but its important to know all the possibilities nonetheless. Yes, we can create Functions (really!) at run-time, as long as everything is a string and new lines are separated by colons or a line feed. This approach is generally fine for small functions, but it can get really confusing and hard to debug as the lines of code increase.

sFunc = "Function ExecuteTest"
sFunc = sFunc & vbLf
sFunc = sFunc & "MsgBox ""ExecuteTest executed."""
sFunc = sFunc & vbLf
sFunc = sFunc & "End Function"
 
Execute sFunc
 
Call ExecuteTest()

We can write the same code above using colons (:) as well:

Execute "Function ExecuteTest : MsgBox ""ExecuteTest executed."" : End Function"
 
Call ExecuteTest()

Executing QTP Statements

This is where the Execute statement absolutely shines. As stated before, RelevantCodes[1]One executes all keywords through Execute statement. It retrieves keywords from the Excel Table as strings at runtime, creates the relevant hierarchies, and executes the hierarchies with chosen events. The concept here and the concepts covered by previous examples will remain the same: we create action strings and execute them. The last example in this topic will show how different strings can be joined together to implement events on supplied test-objects (as strings).

Let’s start with a quick example to check if our target browser exists:

strBrowser = "Browser(""title:=Google"")"
 
Execute "MsgBox " & strBrowser & ".Exist(0)"

The above code can also be written with Eval as well, enabling us to retrieve the value directly instead of using the workaround approach if we were to use Execute:

strBrowser = "Browser(""title:=Google"")"
 
bExist = Eval(strBrowser & ".Exist(0)")

The above statement when executed does the same operation as it would when you would verify the browser existence using an inline DP statement: Msgbox Browser("title:=Google").Exist(0). Let’s consider another example where we create an event on a WebEdit object by creating an object hierarchy through strings at run time.

strBrowser = "Browser(""title:=Google"")"  'Browser("title:=Google")
strPage    = "Page(""title:=Google"")"     'Page("title:=Google")
strText    = "WebEdit(""name:=q"")"        'WebEdit("name:=q")
strEvent   = "Set ""Execute Test"""        'Set "Execute Test"

Execute strBrowser & "." & strPage & "." & strText & "." & strEvent

It does look interesting, doesn’t it? The same approach can be used if you are using Object Repository instead of Descriptive Programming; simply replace the Programmatic Descriptions with the Logical Descriptions in your OR, parse everything in a string and Execute it!

The example below shows how QTP code can be executed into succession through strings. The last 4 statements show how all strings are combined together to 1. Enter the search terms, 2. Click Search Button, 3. Synchronize and 4. Navigate back to the Google search page.

strBrowser = "Browser(""title:=.*Google.*"")"      'Browser("title:=Google")
strPage    = "Page(""title:=.*Google.*"")"         'Page("title:=Google")
strText    = "WebEdit(""name:=q"")"                'WebEdit("name:=q")
strButton  = "WebButton(""value:=Google Search"")" 'WebButton("value:=Google Search")
strEvent   = "Set ""Execute Test"""                'Set "Execute Test"
strClick   = "Click"                               'Click
strSync    = "Sync"                                'Sync
strBack    = "Back"                                'Back

Execute strBrowser & "." & strPage & "." & strText & "." & strEvent
Execute strBrowser & "." & strPage & "." & strButton & "." & strClick
Execute strBrowser & "." & strSync
Execute strBrowser & "." & strBack

The above strings are equivalent to the following QTP code:

Browser("title:=.*Google.*").Page("title:=.*Google.*").WebEdit("name:=q").Set "Execute Test"
Browser("title:=.*Google.*").Page("title:=.*Google.*").WebButton("value:=Google Search").Click
Browser("title:=.*Google.*").Sync
Browser("title:=.*Google.*").Back

Closing Remarks

I hope this article has covered most of the common (and uncommon) uses of Eval and Execute. I’m sure you’ll find areas in your framework where these 2 techniques will make things cleaner and more dynamic. If there is something I have omitted, please feel free to share it with us. I hope you guys find this article useful :)