In the past few weeks, I have seen a lot of new topics on the use of custom DLLs. VBScript’s lack of certain functionality and slow performance, more and more QTP Engineers are turning towards their custom DLLs to simplify and speed-up and simplify part of their framework design. This article shows how the DLLs can be loaded to QTP and their methods accessed with the help of DOTNetFactory.

The DOTNetFactory Object was introduced with QuickTest Professional version 9.1. If you are using version 9.0 or less, the below code may not work ¹ [Credits go to Christian for this update].

I have used VB.NET for this article, but the same principles should apply for any DLL you create. Below is a snapshot of my code in VS:

VB.NET Code

There are 2 outputs I can retrieve from the code above: myInteger and myString as they are both public methods of the Class.

After building the Project and referencing the DLL saved in one of the Project’s folders (bin or debug), I copied the DLL to my D drive:

DLL File Created

I can now call the methods of the DLL using the following code:

Dim oCustom 
 
Set oCustom = DOTNetFactory.CreateInstance("oNamespace.PublicClass", "D:\\RelevantCodes.dll")
 
MsgBox oCustom.myInteger
MsgBox oCustom.myString

Snapshot of the above code in my QTP window:

QTP Code

Upon running the above code, I will have the following 2 outputs:

oNamespace -> PublicClass -> myInteger

oNamespace -> PublicClass -> myString

I hope you find this article useful :)

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.

photo credit: jonathansin

This is the 6th article in the DOTNetFactory Series. The first 5 articles cover the basics of creating a user form and adding a control to it. Like the previous article, this will also be a little fast-paced and will cover how to create a Custom form and add a RadioButton control to it. If you have any doubts with the content in this article, or the previous, please post your comments and I will try to answer them as soon as possible.

Similar to creating a Form, a Text Box and a Button Control, we will use .CreateInstance to create an instance of RadioButton Control as well.

Set oRadioButton = DOTNetFactory.CreateInstance("System.Windows.Forms.RadioButton", "System.Windows.Forms")

Similar to the objects we’ve worked in the preceeding lessons, we will again have to define a point where the RadioButton will be placed.

Set oPoint = DotNetFactory.CreateInstance("System.Drawing.Point", "System.Drawing", x, y)
 
With oPoint
	.x = 20
	.y = 20
End With
 
oRadioButton.Location = oPoint

Also, we must add some Text to the RadioButton so its easily distinguishable. It can be done by using the .Text method:

oRadioButton.Text = "RadioButton"

Putting it all together

Set oForm = DotNetFactory.CreateInstance("System.Windows.Forms.Form", "System.Windows.Forms")
Set oButton = DotNetFactory.CreateInstance("System.Windows.Forms.Button", "System.Windows.Forms")
Set oRadioButton = DOTNetFactory.CreateInstance("System.Windows.Forms.RadioButton", "System.Windows.Forms")
 
Set oPoint = DotNetFactory.CreateInstance("System.Drawing.Point", "System.Drawing", x, y)
 
'RadioButton Location
With oPoint
	.x = 20
	.y = 20
End With
 
'RadioButton Properties
With oRadioButton
	.Text = "RadioButton"
	'Give the RadioButton a name property
	.Name = "btnSample"
	.Location = oPoint
End With
 
'Button Location
With oPoint
	.x = 20
	.y = 50
End With
 
'Button Properties
With oButton
	.Location = oPoint
	.Width = 100
	.Text = "Close Form"
End with
 
'Add Controls
With oForm
	.Controls.Add oRadioButton
	'Adding a Cancel Button
	.CancelButton = oButton
	.Controls.Add oButton
End with
 
'Show Dialog
oForm.ShowDialog
 
'Output the entered Text:
MsgBox "RadioButton Selected: " & oRadioButton.Checked

Executing the code above will display a form control like below:

DOTNetFactory: Adding a Radio Button Control

I had the RadioButton selected and after clicking the WebButton, I received the following output from QTP:

QTP Output for a Selected RadioButton

In the next topic in this series, we will learn how to create a ComboBox control using DOTNetFactory.

In this Series

1. QTP & DOTNetFactory – Creating a Custom Form
2. QTP & DOTNetFactory – Adding a Text Box Control
3. QTP & DOTNetFactory – Adding a Button Control
4. QTP & DOTNetFactory – Adding a CheckBox Control
5. QTP & DOTNetFactory – Creating a Custom Form with Multiple Objects
6. QTP & DOTNetFactory – Adding a RadioButton {Currently Viewed}
7. QTP & DOTNetFactory – Adding a ComboBox – Coming Soon!

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.

In this article, we will see how we can add and use multiple objects in a user form and the code below will pretty much sum it up.. It will cover the concepts discussed in the previous 4 articles. If you have any doubts on this topic or any topics in the earlier chapters, please ask :)

With DOTNetFactory
	'Form
	Set oForm = .CreateInstance("System.Windows.Forms.Form", "System.Windows.Forms")
	'Button
	Set oButton = .CreateInstance("System.Windows.Forms.Button", "System.Windows.Forms")
	'CheckBox
	Set oCheckBox = .CreateInstance("System.Windows.Forms.CheckBox", "System.Windows.Forms")
	'TextBox
	Set oTextBox = .CreateInstance("System.Windows.Forms.TextBox", "System.Windows.Forms")
 
	'Point
	Set oPoint = .CreateInstance("System.Drawing.Point", "System.Drawing", x, y)
End With
 
CONST txtWidth = 150
CONST pntStart = 20
 
'TextBox
With oPoint
	.x = pntStart
	.y = pntStart
End With
With oTextBox
	.Location = oPoint
	.Width = txtWidth
	.Name = "txtSample"
	.Text = "Enter a value"
End With
 
'CheckBox
With oPoint
	'Place the CheckBox to the right of the TextBox
	.x = pntStart + txtWidth + 20
	.y = 20
End With
With oCheckBox
	.Location = oPoint
	.Name = "chkSample"
	.Text = "CheckBox"
End With
 
'Button
With oPoint
	.x = pntStart
	.y = pntStart + 40
End With
With oButton
	.Location = oPoint
	.Width = CInt(oForm.Width) - (3*pntStart)
	.Text = "Close Form"
End With
 
'Form
With oForm
	'Set Form Height
	.Height = 200
	.Controls.Add oTextBox
	.Controls.Add oCheckBox
	'Adding a Cancel Button
	.CancelButton = oButton
	.Controls.Add oButton
End with
 
'Show Dialog
oForm.ShowDialog
 
With oTextBox
	If LCase(.Text) = "enter a value" Then
		MsgBox "You did not enter a value in the Text Box Control"
	Else
		MsgBox "New Text Box value: " & .Text
	End If
End with
 
With oCheckBox
	Dim sStatus
	sStatus = "ON"
	If CBool(.Checked) = False Then sStatus = "OFF"
	MsgBox "CheckBox Status: " & sStatus
End with

Executing the code above will display a form control:

A DOTNetFactory Form

In the next topics in this series, ComboBox and RadioButtons will be covered.

I hope you find this article useful.

In this Series

1. QTP & DOTNetFactory – Creating a Custom Form
2. QTP & DOTNetFactory – Adding a Text Box Control
3. QTP & DOTNetFactory – Adding a Button Control
4. QTP & DOTNetFactory – Adding a CheckBox Control
5. QTP & DOTNetFactory – Creating a Custom Form with Multiple Objects {Currently viewing}
6. QTP & DOTNetFactory – Adding a RadioButton
7. QTP & DOTNetFactory – Adding a ComboBox – Coming Soon!

If you have any questions, please ask them in the comments section. If your information is to be treated as confidential, please use the Contact Form to send me an e-mail instead.

This is the 4th article in the DOTNetFactory Series. The first 3 articles cover the basics of creating a user form and adding a control to it. This article will be a little more fast-paced and will cover how to create a Custom form and add a CheckBox control to it.

Similar to creating a Form, a Text Box and a Button Control, we will use .CreateInstance to create a CheckBox Control as well.

Set oCheckBox = DOTNetFactory.CreateInstance("System.Windows.Forms.CheckBox", "System.Windows.Forms")

Also, just like a Text Box and a Button, the CheckBox will have to be positioned somewhere in the form, thus, we will again define a Point object:

Set oPoint = DotNetFactory.CreateInstance("System.Drawing.Point", "System.Drawing", x, y)
 
With oPoint
	.x = 20
	.y = 20
End With
 
oCheckBox.Location = oPoint

Also, we must add some Text to the CheckBox so its easy to identify if we should check or, or keep it unchecked. It can be done by using the .Text method:

oCheckBox.Text = "CheckBox"

Putting it all together

Set oForm = DotNetFactory.CreateInstance("System.Windows.Forms.Form", "System.Windows.Forms")
Set oButton = DotNetFactory.CreateInstance("System.Windows.Forms.Button", "System.Windows.Forms")
Set oCheckBox = DOTNetFactory.CreateInstance("System.Windows.Forms.CheckBox", "System.Windows.Forms")
 
Set oPoint = DotNetFactory.CreateInstance("System.Drawing.Point", "System.Drawing", x, y)
 
'CheckBox Location
With oPoint
	.x = 20
	.y = 20
End With
 
'CheckBox Properties
With oCheckBox
	.Text = "CheckBox"
	'Give the checkbox a name property
	.Name = "chkSample"
	.Location = oPoint
End With
 
'Button Location
With oPoint
	.x = 20
	.y = 50
End With
 
'Button Properties
With oButton
	.Location = oPoint
	.Width = 100
	.Text = "Close Form"
End with
 
'Add Controls
With oForm
	.Controls.Add oCheckBox
	'Adding a Cancel Button
	.CancelButton = oButton
	.Controls.Add oButton
End with
 
'Show Dialog
oForm.ShowDialog
 
'Output the entered Text:
MsgBox "CheckBox Selected: " & oCheckBox.Checked

Executing the code above will display a form control:

DOTNetFactory: Adding a CheckBox

I had the checkbox in the “ON” position and after clicking the button, I received the following output from QTP:

Adding a CheckBox Control: QTP Output

In the next topic in this series, we will learn how to create a CheckBox control using DOTNetFactory.

I hope you find this article useful.

In this Series

1. QTP & DOTNetFactory – Creating a Custom Form
2. QTP & DOTNetFactory – Adding a Text Box Control
3. QTP & DOTNetFactory – Adding a Button Control
4. QTP & DOTNetFactory – Adding a CheckBox Control {Currently viewing}
5. QTP & DOTNetFactory – Creating a Custom Form with Multiple Objects
6. QTP & DOTNetFactory – Adding a RadioButton
7. QTP & DOTNetFactory – Adding a ComboBox – Coming Soon!

If you have any questions, please ask them in the comments section. If your information is to be treated as confidential, please use the Contact Form to send me an e-mail instead.

The last 2 articles in this series discussed creation of a Custom Form and addition of a Text Box Control to the form. This article shows how to add a Button control to the form using DOTNetFactory. Since most of the basics have been discussed in the previous articles, this one will be quite fast-paced.

Similar to creating a Form and Text Box, we will use .CreateInstance to create a Button Control.

Set oButton = DotNetFactory.CreateInstance("System.Windows.Forms.Button", "System.Windows.Forms")

Also, just like a Text Box, the button will have to be positioned somewhere in the form, thus, we will again define a Point object:

Set oPoint = DotNetFactory.CreateInstance("System.Drawing.Point", "System.Drawing", x, y)
 
With oPoint
	.x = 20
	.y = 50
End With
 
oButton.Location = oPoint

When adding a Button, you might also want to add some Text to it, so its easily distinguishable:

oButton.Text = "Close Form"

In this example, the button we are adding will be a Cancel button type that will exit the form once clicked.

oForm.CancelButton = oButton

Putting it all together

Let’s add a Text Box Control, and use QTP to output the entered Text using MsgBox.

Set oForm = DotNetFactory.CreateInstance("System.Windows.Forms.Form", "System.Windows.Forms")
Set oButton = DotNetFactory.CreateInstance("System.Windows.Forms.Button", "System.Windows.Forms")
Set oText = DotNetFactory.CreateInstance("System.Windows.Forms.TextBox", "System.Windows.Forms")
 
Set oPoint = DotNetFactory.CreateInstance("System.Drawing.Point", "System.Drawing", x, y)
 
'Text Box
With oPoint
	.x = 20
	.y = 20
End With
 
With oText
	.Location = oPoint
	.Width = 100
End With
 
'Button
With oPoint
	.x = 20
	.y = 50
End With
 
With oButton
	.Location = oPoint
	.Width = 100
	.Text = "Close Form"
End with
 
'Add Controls
With oForm
	.Controls.Add oText
	'Adding a Cancel Button
	.CancelButton = oButton
	.Controls.Add oButton
End with
 
'Show Dialog
oForm.ShowDialog
 
'Output the entered Text:
MsgBox oText.Text

Executing the code above will display a form control:

Adding a Button Control to a Custom Form

I entered Relevant Codes in the text box and clicked the button to get the following output from QTP:

Button Control Example: QTP Output

In the next topic in this series, we will learn how to create a CheckBox control using DOTNetFactory.

I hope you find this article useful.

In this Series

1. QTP & DOTNetFactory – Creating a Custom Form
2. QTP & DOTNetFactory – Adding a Text Box Control
3. QTP & DOTNetFactory – Adding a Button Control {Currently viewing}
4. QTP & DOTNetFactory – Adding a CheckBox Control
5. QTP & DOTNetFactory – Creating a Custom Form with Multiple Objects
6. QTP & DOTNetFactory – Adding a RadioButton
7. QTP & DOTNetFactory – Adding a ComboBox – Coming Soon!

If you have any questions, please ask them in the comments section. If your information is to be treated as confidential, please use the Contact Form to send me an e-mail instead.

In this article, we will discuss how to add the Text Box control to the user form we created in the previous article, Creating a Custom Form. CreateInstance has also been discussed in the previous article, and just like a Form, we will use .CreateInstance again for the Text Box control.

Set oText = DotNetFactory.CreateInstance("System.Windows.Forms.TextBox", "System.Windows.Forms")

Above, the TypeName is System.Windows.Forms.TextBox. This means, just like the Form Control, a TextBox is also a part of the System.Windows.Forms namespace. Unlike the Form Control however, we cannot use .Show and .ShowDialog methods. Instead, we will insert the Text Box in the Form Control.

Set oForm = DotNetFactory.CreateInstance("System.Windows.Forms.Form", "System.Windows.Forms")
Set oText = DotNetFactory.CreateInstance("System.Windows.Forms.TextBox", "System.Windows.Forms")
oForm.ShowDialog

After executing the statements above, you will notice that the text box didn’t appear in the Form? Well, that is because even though we created an edit box object, we have not yet added it to the Form (oForm) Control. We have not even defined the size and where it will be located on the form. Before we add the oText objec to the form, we must first understand the System.Drawing namespace.

Set oPoint = DotNetFactory.CreateInstance("System.Drawing.Point", "System.Drawing", x, y)

Now, oPoint will enable us to place individual controls to be added to the form on given x and y coordinates. Below is a demonstration of how to place the Text Box control 20 points from the left, and 20 points to the top of the form:

Set oPoint = DotNetFactory.CreateInstance("System.Drawing.Point", "System.Drawing", x, y)
 
With oPoint
	.x = 20
	.y = 20
End With
 
'Our Text Control will now have the coordinates added above
oText.Location = oPoint

and executing the following statement will add the Text Box control to the form:

oForm.Controls.Add oText

When we add the Text Box control to the form, it will be placed on the stated x and y coordinates. Finally, when we put all the pieces together, we will have the following code and form:

Set oForm = DotNetFactory.CreateInstance("System.Windows.Forms.Form", "System.Windows.Forms")
Set oText = DotNetFactory.CreateInstance("System.Windows.Forms.TextBox", "System.Windows.Forms")
 
'System.Drawing.Point Instance
Set oPoint = DotNetFactory.CreateInstance("System.Drawing.Point", "System.Drawing", x, y)
 
'Text Box Location 
With oPoint
	.x = 20
	.y = 20
End With
 
'Text Box Properties
With oText
	.Location = oPoint
	.Width = 100
End With
 
oForm.Controls.Add oText
 
oForm.ShowDialog

Form:

Text Box Control added to a Custom Form

In the next topic in this series, we will learn how to create and add a Button control using DOTNetFactory.

I hope you find this article useful.

In this Series

1. QTP & DOTNetFactory – Creating a Custom Form
2. QTP & DOTNetFactory – Adding a Text Box Control {Currently viewing}
3. QTP & DOTNetFactory – Adding a Button Control
4. QTP & DOTNetFactory – Adding a CheckBox Control
5. QTP & DOTNetFactory – Creating a Custom Form with Multiple Objects
6. QTP & DOTNetFactory – Adding a RadioButton
7. QTP & DOTNetFactory – Adding a ComboBox – Coming Soon!

If you have any questions, please ask them in the comments section. If your information is to be treated as confidential, please use the Contact Form to send me an e-mail instead.

Recently, I worked on a requirement in which I was asked to create a custom user-form that lets users choose how they want automated tests to be run. I first thought of creating a windows application using VB.NET, but, after some consideration I decided to use DOTNetFactory instead. This was quite a good choice since I did not need Visual Basic or Visual Studio installed on the PC where I develop my framework. In this series of articles, we will discover how to use the DOTNetFactory to create a user form and how to add different object types to it.

When we use DOTNetFactory, we must first create a COM interface using the CreateInstance method. This interface is passed as an argument (object) which has several methods that we’re going to use in this series.

According to book Scripting QTP, Chapter 14, by Dani Vainstein, the syntax for creating an instance of .NET is:

Set var_CreateInstance = DOTNetFactory.CreateInstance (TypeName [,Assembly] [,args])

TypeName: The full name of the object type, for example, System.Windows.Forms.Form.

Assembly: Optional. If the assembly is preloaded in the registry, you do not need to enter it. Otherwise, you should enter the full path name, for example, System.Windows.Forms. If you want to create an instance of a type in the GAC (Global Assembly Cache), you can enter the short name, for example, Forms.

args: Optional. The required arguments, if any, for the specified TypeName and/or Assembly

Let’s use .CreateInstance to create a simple user form using System.Windows.Forms.Form as the TypeName. A Form object in .NET is part of the System.Windows.Forms namespace. .NET namespaces are beyond the scope of this article, and will be discussed in detail in an upcoming article on VB.NET.

In QTP, we can retrieve the COM interface created by the .CreateInstance method using the ‘Set’ statement:

Set oForm = DOTNetFactory.CreateInstance("System.Windows.Forms.Form", "System.Windows.Forms")

We have just created a user form using DOTNetFactory!

You might wonder though, if we have really created a user form, where is it? Why doesn’t it display when we execute the above statement? That is because, as I mentioned earlier that the returned COM interface will have several methods. The above form has .Show and .ShowDialog methods which enable the form to be displayed:

Set oForm = DOTNetFactory.CreateInstance("System.Windows.Forms.Form", "System.Windows.Forms")
oForm.Show

Set oForm = DOTNetFactory.CreateInstance("System.Windows.Forms.Form", "System.Windows.Forms")
 
'Adds a title to the form
oForm.Text = "Sample Custom Form"
 
oForm.ShowDialog

An Empty Form

Both methods will display the form on your desktop. However, there is a slight difference between the two. When you execute oForm.Show, you will note that the form will be displayed and the test executing will immediately move on to the next line. However, with oForm.ShowDialog, QTP will wait until we perform an event on the form before execution moves on to the next statement in our test. This is the method we’re interested in, because we will be provided QTP with several inputs using these form. In this series, we will be using .ShowDialog extensively.

In the next topic in this series, we will learn how to create a Text Box using DOTNetFactory.

I hope you find this article useful.

References

1. Scripting QTP by Dani Vainstein – Chapter 14 – DOTNetFactory

In this Series

1. QTP & DOTNetFactory – Creating a Custom Form {Currently viewing}
2. QTP & DOTNetFactory – Adding a Text Box Control
3. QTP & DOTNetFactory – Adding a Button Control
4. QTP & DOTNetFactory – Adding a CheckBox Control
5. QTP & DOTNetFactory – Creating a Custom Form with Multiple Objects
6. QTP & DOTNetFactory – Adding a RadioButton
7. QTP & DOTNetFactory – Adding a ComboBox – Coming Soon!

If you have any questions, please ask them in the comments section. If your query is confidential, please use the Contact Form to send me an e-mail instead.